0000-                133                      .FI
0000-                134              .FI
0000-                135      ;
0000-                136      ; ********************************************************
0000-                137      ;
F800-                138      MPROM   .EQ     $F800                   ; Normal monitor position at top of memory
00E3-                139      MONDP   .EQ     BASE+$0300/256          ; Direct page for monitor
0000-                140      ;
0000-                141      ; VDU Configuration
0019-                142      ROWS    .EQ     25                      ; Number of rows on display.
0050-                143      COLS    .EQ     VDU&$F8                 ; Number of characters per row, 40 or 80
0800-                144      PSIZE   .EQ     VDU&$F8/10*256          ; Size of display memory in total, $0400 (1K) or $0800 (2K)
000C-                145      PAGHI   .EQ     12                      ; Page address register, high byte
000E-                146      CURHI   .EQ     14                      ; Cursor address register, high byte
0000-                147      ;
0000-             S  148              .DO     VDU&$F8=40              ; Location of memory that 40-Column VDU uses:
0000-             S  149      VPAGE   .EQ     BASE+$400               ;       Standard $0400
0000-             S  150                                              ;       Flex $E400
0000-             S  151      ;
0000-             S  152                                              ; Location of CRT controller on 40-column VDU card:
0000-             S  153      CRTC    .EQ     BASE+$0800              ;       Standard $0800
0000-                154              .FI                             ;       Flex $E800
0000-                155      ;
0000-                156              .DO     VDU=80                  ; Location of memory that 80-Column VDU uses:
F000-                157      VPAGE   .EQ     BASE+$1000              ;       Standard $1000
0000-                158                                              ;       Flex $F000
0000-                159      ;
0000-                160                                              ; Location of CRT controller on 80-column VDU card:
0000-             S  161              .DO     BASE=$0000
0000-             S  162      CRTC    .EQ     $1840                   ;       Standard $1840
0000-                163              .FI
0000-                164              .DO     BASE=$E000
E840-                165      CRTC    .EQ     $E840                   ;       Flex $E840
0000-                166              .FI
0000-                167              .FI
0000-                168      ;
0007-                169      WRPMSK  .EQ     PSIZE/256-1             ; Mask to wrap address within PSIZE, 3 (40-column) or 7 (80-column)
0000-                170      ;
0040-                171      DRIVE   .EQ     $40                     ; Drive to bootstrap from - Drive 0 $40, Drive 1 change to $80
EA00-                172      FLOPY   .EQ     BASE+$0A00              ; Location of floppy disc controller:
0000-                173                                              ;       Standard $0A00
0000-                174                                              ;       Flex $EA00
EA00-                175      FDCC    .EQ     FLOPY                   ; Command register
EA00-                176      FDCS    .EQ     FDCC                    ; Status register
EA01-                177      FDCP    .EQ     FLOPY+1                 ; Parameter register
EA01-                178      FDCR    .EQ     FDCP                    ; Result register
EA02-                179      FDRST   .EQ     FLOPY+2                 ; Reset register
EA04-                180      FDCD    .EQ     FLOPY+4                 ; Data register
0000-                181      ;
E980-                182      KVIA    .EQ     BASE+$0980              ; Location of Versatile Interface Adaptor
E980-                183      KORB    .EQ     KVIA+$0                 ; Output register B
E980-                184      KIRB    .EQ     KORB                    ; Input register B
E981-                185      KORA    .EQ     KVIA+$1                 ; Output register A
E981-                186      KIRA    .EQ     KORA                    ; Input register A
E982-                187      KDDRB   .EQ     KVIA+$2                 ; Data direction register B
E983-                188      KDDRA   .EQ     KVIA+$3                 ; Data direction register A
E984-                189      KT1CL   .EQ     KVIA+$4                 ; Timer 1 counter low
E985-                190      KT1CH   .EQ     KVIA+$5                 ; Timer 1 counter high
E986-                191      KT1LL   .EQ     KVIA+$6                 ; Timer 1 latch low
E987-                192      KT1LH   .EQ     KVIA+$7                 ; Timer 1 latch high
E988-                193      KT2CL   .EQ     KVIA+$8                 ; Timer 2 counter low
E989-                194      KT2CH   .EQ     KVIA+$9                 ; Timer 2 counter high
E98A-                195      KSR     .EQ     KVIA+$A                 ; Shift register
E98B-                196      KACR    .EQ     KVIA+$B                 ; Auxiliary control register
E98C-                197      KPCR    .EQ     KVIA+$C                 ; Peripheral control register
E98D-                198      KIFR    .EQ     KVIA+$D                 ; Interrupt flag register
E98E-                199      KIER    .EQ     KVIA+$E                 ; Interrupt enable register
E98F-                200      KORA2   .EQ     KVIA+$F                 ; Input/output register A without hand shake
0000-                201      ;
0F00-                202      INTDEL  .EQ     15*256                  ; Delay for single instruction trace is 15 cycles
0040-                203      T1IFLG  .EQ     %01000000               ; Interrupt flag position for timer 1
0010-                204      CB1FLG  .EQ     %00010000               ; Interrupt flag position for keyboard strobe on CB1
0000-                205      ;
00EF-                206      IKPCR   .EQ     %11101111               ; Initial value for peripheral control register,
0000-                207                                              ;       bit 0           CA1 control from printer, positive edge interrupt,
0000-                208                                              ;                           but not used in this monitor
0000-                209                                              ;       bits 1-3        CA2 control to strobe printer, normally high
0000-                210                                              ;       bit 4           CB1 control, negative edge keyboard interrupt
0000-                211                                              ;       bits 5-7        CB2 control, cassette output initially set high
0000-                212      ;
00D0-                213      IKIER   .EQ     %11010000               ; Interrupt enable register control
0000-                214                                              ;       bit 4           CB1 keyboard interrupt enable
0000-                215                                              ;       bit 6           timer 1 interrupt enable
0000-                216                                              ;       bit 7           set interrupts enabled
0000-                217                                              ;       other enables not altered
0000-                218      ;
0002-                219      PSTRB   .EQ     %00000010               ; bit position in PCR of printer strobe, to toggle CA2
0020-                220      COPBIT  .EQ     %00100000               ; bit position in PCR of cassette output, to toggle CB2
0000-                221      ;
003F-                222      SWIOP   .EQ     $3F                     ; Software interrupt used for breakpoints
0000-                223      ;
0052-                224      BUFLEN  .EQ     81+1                    ; Buffer up to 80 characters from keyboard
0000-                225      ;
002A-                226      PROMPT  .EQ     '*'                     ; Monitor prompt
007F-                227      RUBCH   .EQ     $7F                     ; Keyboard code that does rubout operation
007F-                228      BSPACE  .EQ     $7F                     ; Code that backspaces VDU, also used to do rubout
000A-                229      LF      .EQ     $0A                     ; Linefeed
000D-                230      CR      .EQ     $0D                     ; Carriage return
0020-                231      SPACE   .EQ     $20                     ; Blank space
002C-                232      COMMA   .EQ     ','                     ; The comma symbol
002D-                233      MINUS   .EQ     '-'                     ; The minus symbol
000C-                234      FFEED   .EQ     $0C                     ; Code used as clear screen command
003B-                235      SEMIC   .EQ     ';'                     ; The semicolon symbol
0000-                236      ;
0010-                237      IRQ     .EQ     $10
0004-                238      ZERO    .EQ     $04
0000-                239      ;
0000-                240      ;       Definitions of variables in page 03 / E3
0000-                241      ;       ----------------------------------------
0000-                242      ;
E35B-                243      ISTACK  .EQ     BASE+$035B              ; Stack pointer starts here
E35B-                244      RTAB1   .EQ     BASE+$035B              ; RAM table 1 starts here
0000-                245      ;
0000-                246      ;       This table is copied from ROM on start-up
0000-                247      ;
E35B-                248      STACK   .EQ     BASE+$035B              ; Position of stack pointer when empty
E35D-                249      NTRACE  .EQ     BASE+$035D              ; Number of instructions to trace before stopping
E35F-                250      BSECHO  .EQ     BASE+$035F              ; Character sent to backspace display
E360-                251      ECHOF   .EQ     BASE+$0360              ; Keyboard buffer/echo control
0000-                252                                              ;       bits 0-5        don't care
0000-                253                                              ;       bit 6           echo console input to console output if set
0000-                254                                              ;       bit 7           buffer input lines, allow rubout if set
0000-                255      ;
E361-                256      PFLAG   .EQ     BASE+$0361              ; Printer control flag, echo console output to printer if nonzero
E362-                257      PNEW    .EQ     BASE+$0362              ; This character not sent to printer
E363-                258      DELCNT  .EQ     BASE+$0363              ; Non-zero delay count for cassette, controls baud rate
E365-                259      COPADR  .EQ     BASE+$0365              ; Address for console output
E367-                260      CINADR  .EQ     BASE+$0367              ; Address for console input
E369-                261      CASOPA  .EQ     BASE+$0369              ; Address for cassette output
E36B-                262      CASINA  .EQ     BASE+$036B              ; Address for cassette input
E36D-                263      PRINT1  .EQ     BASE+$036D              ; Address of printer output routine
E36F-                264      FUNCTI  .EQ     BASE+$036F              ; Address of VDU function table
E371-                265      CMNDI   .EQ     BASE+$0371              ; Address of monitor command table
E373-                266      IRQRTS  .EQ     BASE+$0373              ; Address to go to on timer 1 interrupt
E375-                267      LINEPT  .EQ     BASE+$0375              ; Address of memory input line, 0 if none
E377-                268      IRESV   .EQ     BASE+$0377              ; Address of reserved vector routine
E379-                269      ISWI3   .EQ     BASE+$0379              ; Address of SWI1 routine
E37B-                270      ISWI2   .EQ     BASE+$037B              ; Address of SWI2 routine
E37D-                271      IFIRQ   .EQ     BASE+$037D              ; Address of FIRQ routine
E37F-                272      IIRQ    .EQ     BASE+$037F              ; Address of IRQ routine
E381-                273      ISWI    .EQ     BASE+$0381              ; Address of SWI routine
E383-                274      INMI    .EQ     BASE+$0383              ; Address of NMI routine
E385-                275      OFFSET  .EQ     BASE+$0385              ; Cassette load offset
0000-                276      ;
0000-                277      ;       General variables for monitor use
0000-                278      ;
E387-                279      HEADST  .EQ     BASE+$0387              ; Static head pointer into line buffer
E389-                280      HEADDY  .EQ     BASE+$0389              ; Dynamic head pointer into line buffer
E38B-                281      TAIL    .EQ     BASE+$038B              ; Tail pointer into line buffer
E38D-                282      MSTACK  .EQ     BASE+$038D              ; stack saved whilst memory interpreting
E38F-                283      CROW    .EQ     BASE+$038F              ; current row of cursor on display
E390-                284      CCOL    .EQ     BASE+$0390              ; current column of cursor on display
E391-                285      CPAGE   .EQ     BASE+$0391              ; current start of display page in memory
E393-                286      MSAV    .EQ     BASE+$0393              ; Saved address for memory command
E395-                287      GSAV    .EQ     BASE+$0395              ; Saved address for go command
E397-                288      NAME    .EQ     BASE+$0397              ; Saved name for cassette input output
E39D-                289      CSSTRT  .EQ     BASE+$039D              ; Saved cassette output start address
E39F-                290      CSEND   .EQ     BASE+$039F              ; Saved cassette output end address
E3A1-                291      ONLINE  .EQ     BASE+$03A1              ; flag set to zero when find or in input line
E3A2-                292      LASTC   .EQ     BASE+$03A2              ; Saved last character from input line current
E3A3-                293      CBREAK  .EQ     BASE+$03A3              ; Address of breakpoint, $FFFF if none
E3A5-                294      NBREAK  .EQ     BASE+$03A5              ; number of breakpoints to ignore before stopping user
E3A7-                295      CINST   .EQ     BASE+$03A7              ; user instruction at breakpoint address
E3A8-                296      CTRACE  .EQ     BASE+$03A8              ; number of instructions left to trace before stopping user
E3AA-                297      USRSTK  .EQ     BASE+$03AA              ; Saved user-stack pointer when user halted
E3AC-                298      TEMP    .EQ     BASE+$03AC              ; Temporary storage
E3AE-                299      BUFFER  .EQ     BASE+$03AE              ; line input buffer
0000-                300      ;               BASE+$03FF              ; end of line input buffer
0000-                301      ;
0000-                302      ;       Memory Maps
0000-                303      ;       -----------
0000-                304      ;
0000-                305      ;       Original Acorn
0000-                306      ;       $0000-$03FF     Monitor System RAM (IC5,6)
0000-                307      ;       $0400-$07FF     40-column Teletext video memory
0000-                308      ;       $0800-$08FF     40-column Teletext 6845 CRTC
0000-                309      ;;      $0900-$09FF     6522 VIA ($0980)
0000-                310      ;               REGA    b6-b0   printer output
0000-                311      ;                       b7      printer busy input
0000-                312      ;               REGB    b6-b0   keyboard ASCII input
0000-                313      ;                       b7      cassette input
0000-                314      ;               CA1             input from printer acknowledge (not used)
0000-                315      ;               CA2             output strobe to printer
0000-                316      ;               CB1             input strobe from keyboard
0000-                317      ;               CB2             output to cassette
0000-                318      ;               Timer1          used to single step
0000-                319      ;               Timer2          unused
0000-                320      ;       $0A00-$0A7F     8271 floppy disk controller
0000-                321      ;       $1000-$17FF     80-column VDU video memory
0000-                322      ;       $1800-$187F     80-column 6845 CRTC ($1840)
0000-                323      ;       $2000-$3FFF     User RAM (8K)
0000-                324      ;       $2000-$BFFF     or User RAM (8K+32K)
0000-                325      ;       $F800-$FFFF     Monitor EPROM (IC4)
0000-                326      ;
0000-                327      ;       Flex
0000-                328      ;       $0000-$7FFF     User RAM (32K)
0000-                329      ;       $0000-$BFFF     or User RAM (48K)
0000-                330      ;       $C000-$DFFF     FLEX System RAM (loaded from Disk)
0000-                331      ;       $E000-$E3FF     Monitor System RAM (IC5,6)
0000-                332      ;       $E400-$E7FF     40-column Teletext Video memory
0000-                333      ;       $E800-$E8FF     40-column Teletext 6845 CRTC
0000-                334      ;       $E800-$E87F     80-column 6845 CRTC ($E840)
0000-                335      ;       $E900-$E9FF     6522 VIA ($E980)
0000-                336      ;               REGA    b6-b0   printer output
0000-                337      ;                       b7      printer busy input
0000-                338      ;               REGB    b6-b0   keyboard ASCII input
0000-                339      ;                       b7      cassette input
0000-                340      ;               CA1             input from printer acknowledge (not used)
0000-                341      ;               CA2             output strobe to printer
0000-                342      ;               CB1             input strobe from keyboard
0000-                343      ;               CB2             output to cassette
0000-                344      ;               Timer1          used to single step
0000-                345      ;               Timer2          unused
0000-                346      ;       $EA00-$EA7F     8271 floppy disk controller
0000-                347      ;       $F000-$F7FF     80-column VDU video memory
0000-                348      ;       $F800-$FFFF     Monitor EPROM (IC4)
0000-                349      ;
F800-                350              .OR     MPROM
F800-                351      ;
F800-                352                                      ; ****** Hardware Reset Starts Here ******
F800-                353      ;
F800-86 E3           354 ( 2) RESET:  LDA     #MONDP          ; setup direct page
F802-1F 8B           355 ( 7)         TFR     A,DP
F804-                356              .DP     MONDP
F804-8E FF 25        357 ( 3)         LDX     #PTAB1          ; ROM table start
F807-CE E3 5B        358 ( 3)         LDU     #RTAB1          ; RAM table start
F80A-A6 80           359 ( 7) RST1:   LDA     ,X+             ; copy ROM to RAM
F80C-A7 C0           360 ( 7)         STA     ,U+
F80E-8C FF 51        361 ( 4)         CMPX    #PTAB2          ; until end of table
F811-26 F7           362 ( 3)         BNE     RST1
F813-10 DE 5B        363 ( 6)         LDS     <STACK          ; setup stack pointer
F816-                364      ;
F816-                365              .DO     VER<>495        ; (all versions except 4.95)
F816-BE F7 FE        366 ( 6)         LDX     MPROM-2
F819-8C A5 5A        367 ( 4)         CMPX    #$A55A          ; check for extra ROM
F81C-26 04           368 ( 3)         BNE     STRT1           ; not there
F81E-AD 9F F7 FC     369 (13)         JSR     [MPROM-4]       ; else call it
F822-                370              .FI
F822-                371      ;
F822-             S  372              .DO     VER=495         ; (version 4.95 only)
F822-             S  373              .DB     $17,$06,$63     ; 'LBSR CONCHR-3'
F822-             S  374              NOP
F822-             S  375              NOP
F822-             S  376              NOP
F822-             S  377              NOP
F822-             S  378              NOP
F822-             S  379              NOP
F822-             S  380              NOP
F822-             S  381              NOP
F822-             S  382              NOP
F822-                383              .FI
F822-                384      ;
F822-CE FB EA        385 ( 3) STRT1:  LDU     #BACK           ; Put monitor return on to stack
F825-34 40           386 ( 7)         PSHS    U
F827-CC 00 0C        387 ( 3)         LDD     #$0C
F82A-34 02           388 ( 6) STRT2:  PSHS    A               ; Put dummy registers onto stack
F82C-5A              389 ( 2)         DECB
F82D-26 FB           390 ( 3)         BNE     STRT2
F82F-10 DF AA        391 ( 6)         STS     <USRSTK         ; Save stack pointer
F832-8E E3 AE        392 ( 3)         LDX     #BUFFER         ; Get start of buffer
F835-9F 89           393 ( 5)         STX     <HEADDY         ; and set up pointers
F837-9F 87           394 ( 5)         STX     <HEADST
F839-9F 8B           395 ( 5)         STX     <TAIL
F83B-17 00 E7        396 ( 9)         LBSR    CRTCI           ; Initialise CRT controller
F83E-17 00 D1        397 ( 9)         LBSR    VIAI            ; and VIA chips
F841-0F A2           398 ( 6)         CLR     <LASTC          ; Set no saved character
F843-17 04 00        399 ( 9)         LBSR    BRKOUT          ; Remove if exists
F846-8E FF FF        400 ( 3)         LDX     #$FFFF          ; then set none existing
F849-                401      ;
F849-                402              .DO     VER<>495        ; (all versions except 4.95)
F849-9F A3           403 ( 5)         STX     <CBREAK
F84B-1C EF           404 ( 3)         ANDCC   #$EF            ; CLI: Allow interrupts
F84D-                405              .FI
F84D-                406      ;
F84D-             S  407              .DO     VER=495         ; (version 4.95 only)
F84D-             S  408              JMP     MCASIN
F84D-             S  409              .DB     $EF             ; Packing ?
F84D-                410              .FI
F84D-                411      ;
F84D-                412              .DP     0
F84D-86 2A           413 ( 2) MON:    LDA     #PROMPT         ; Send prompt
F84F-BE E3 75        414 ( 6)         LDX     >LINEPT         ; unless
F852-26 03           415 ( 3)         BNE     MON1            ; memory input
F854-17 01 CA        416 ( 9)         LBSR    CONOUT
F857-                417      ;
F857-B7 E3 A1        418 ( 5) MON1:   STA     >ONLINE         ; Set no CR yet
F85A-86 E3           419 ( 2) PARSE:  LDA     #MONDP
F85C-1F 8B           420 ( 7)         TFR     A,DP            ; Set direct page
F85E-                421              .DP     MONDP
F85E-9E 75           422 ( 5)         LDX     <LINEPT         ; See if mem input,
F860-27 04           423 ( 3)         BEQ     PARSEC          ; if so,
F862-A6 84           424 ( 5)         LDA     ,X              ; then see if null yet
F864-27 41           425 ( 3)         BEQ     MEND            ; End if is null
F866-8D 17           426 ( 7) PARSEC: BSR     CONCHR          ; Get input
F868-27 E3           427 ( 3)         BEQ     MON             ; prompt on CR
F86A-9E 71           428 ( 5)         LDX     <CMNDI          ; else command table search
F86C-17 01 37        429 ( 9)         LBSR    DISPCH
F86F-20 E9           430 ( 3)         BRA     PARSE
F871-                431      ;
F871-                432      ; Enter here for monitor to use memory input line (X) is start of line, ends with a null.
F871-                433      ; multiple input lines are allowed, each line ends with carriage return.
F871-                434      ;
F871-                435      ; Exits with (a) zero if all ok, else (a) is $FF if found null too early,
F871-                436      ; else (a) is character causing error.
F871-                437      ;
F871-                438              .DP     0
F871-34 08           439 ( 6) MEMUSE: PSHS    DP
F873-10 FF E3 8D     440 ( 7)         STS     MSTACK          ; Save stack for return.
F877-BF E3 75        441 ( 6)         STX     LINEPT          ; Save pointer in memory
F87A-7F E3 A2        442 ( 7)         CLR     LASTC           ; Set none saved
F87D-20 CE           443 ( 3)         BRA     MON             ; and call monitor
F87F-86 0D           444 ( 2) CONCHR: LDA     #CR             ; Assume CR now
F881-7D E3 A1        445 ( 7)         TST     ONLINE          ; and if found CR then
F884-27 06           446 ( 3)         BEQ     CON1            ; is correct
F886-8D 08           447 ( 7)         BSR     CONIN           ; Get input
F888-81 0D           448 ( 2)         CMPA    #CR             ; If not CR then
F88A-26 03           449 ( 3)         BNE     CON2            ; done
F88C-7F E3 A1        450 ( 7) CON1:   CLR     ONLINE          ; Set found CR
F88F-39              451 ( 5) CON2:   RTS
F890-                452      ;
F890-                453      ; Console input routine, gets character from keyboard buffer or memory it finds
F890-                454      ; null in memory then returns to to caller with error $FF.
F890-                455      ;
F890-                456              .DP     MONDP
F890-34 18           457 ( 8) CONIN:  PSHS    DP,X
F892-86 E3           458 ( 2)         LDA     #MONDP          ; Set up
F894-1F 8B           459 ( 7)         TFR     A,DP            ; direct page
F896-96 A2           460 ( 4)         LDA     <LASTC          ; Saved one?
F898-27 04           461 ( 3)         BEQ     CON5            ; none saved
F89A-0F A2           462 ( 6)         CLR     <LASTC          ; not saved anymore
F89C-35 98           463 (10)         PULS    DP,X,PC
F89E-                464      ;
F89E-9E 75           465 ( 5) CON5:   LDX     <LINEPT         ; see if mem input
F8A0-27 0E           466 ( 3)         BEQ     CON3            ; no, use buffer
F8A2-A6 80           467 ( 7)         LDA     ,X+             ; Get men value
F8A4-26 0E           468 ( 3)         BNE     CON4            ; ok if not null
F8A6-4A              469 ( 2)         DECA                    ; Set to $FF
F8A7-10 DE 8D        470 ( 6) MEND:   LDS     <MSTACK         ; clear mem
F8AA-0F 75           471 ( 6)         CLR     <LINEPT+0       ; input
F8AC-0F 76           472 ( 6)         CLR     <LINEPT+1
F8AE-35 88           473 ( 8)         PULS    DP,PC           ; and return to caller
F8B0-AD 9F E3 67     474 (13) CON3:   JSR     [CINADR]        ; Get console input
F8B4-9F 75           475 ( 5) CON4:   STX     <LINEPT         ; store new mem pointer
F8B6-35 98           476 (10)         PULS    DP,X,PC
F8B8-                477      ;
F8B8-                478      ; This routine prints the registers from the stack as pointed to by USRSTK,
F8B8-                479      ; then prints USRSTK itself.  Also prints five bytes starting at (PC)
F8B8-                480      ;
F8B8-8E FF 96        481 ( 3) EXREG:  LDX     #TITLES         ; Headings
F8BB-8D 2F           482 ( 7)         BSR     STRING          ; printed first
F8BD-DE AA           483 ( 5)         LDU     <USRSTK
F8BF-C6 04           484 ( 2)         LDB     #$04            ; ie, CC,A,B,DP.
F8C1-A6 C0           485 ( 7) EX1:    LDA     ,U+             ; Get data
F8C3-17 01 D1        486 ( 9)         LBSR    OPARSP          ; output as 2 hex digits
F8C6-5A              487 ( 2)         DECB
F8C7-26 F8           488 ( 3)         BNE     EX1             ; until all 4 output
F8C9-C6 04           489 ( 2)         LDB     #$04            ; ie, X, Y, U, PC
F8CB-AE C1           490 ( 9) EX2:    LDX     ,U++            ; get 2 bytes
F8CD-17 01 A5        491 ( 9)         LBSR    OPXREG          ; as 4 hex digits
F8D0-5A              492 ( 2)         DECB
F8D1-26 F8           493 ( 3)         BNE     EX2             ; until all output
F8D3-9E AA           494 ( 5)         LDX     <USRSTK         ; then put out stack
F8D5-17 01 9D        495 ( 9)         LBSR    OPXREG          ; address.
F8D8-EE 0A           496 ( 7)         LDU     $0A,X           ; Get user PC value
F8DA-8E FF BD        497 ( 3)         LDX     #PCMESS         ; Send
F8DD-8D 0D           498 ( 7)         BSR     STRING          ; title
F8DF-C6 05           499 ( 2)         LDB     #$05            ; then 5 bytes
F8E1-A6 C0           500 ( 7) EX3:    LDA     ,U+
F8E3-17 01 B1        501 ( 9)         LBSR    OPARSP
F8E6-5A              502 ( 2)         DECB
F8E7-26 F8           503 ( 3)         BNE     EX3
F8E9-                504      ;
F8E9-                505      ; Output the string CR, LF to console
F8E9-                506      ;
F8E9-8E FF 93        507 ( 3) OPCRLF: LDX     #SCRLF          ; String address of CR, LF
F8EC-                508      ;
F8EC-                509      ; Output the string pointed to by X until a null,
F8EC-                510      ; leaves X pointing to null+1, other registers intact
F8EC-                511      ;
F8EC-34 02           512 ( 6) STRING: PSHS    A               ; Save A
F8EE-A6 80           513 ( 7) STRNG1: LDA     ,X+             ; Get data
F8F0-27 05           514 ( 3)         BEQ     EOTXT           ; finish if null
F8F2-17 01 2C        515 ( 9)         LBSR    CONOUT          ; else output
F8F5-20 F7           516 ( 3)         BRA     STRNG1          ; and repeat.
F8F7-35 82           517 ( 8) EOTXT:  PULS    A,PC            ; Get A back and return
F8F9-                518      ;
F8F9-                519      ; Calculate apparent address of cursor without allowing for memory wrap around, result in D.
F8F9-                520      ;
F8F9-                521      CCOFST:
F8F9-                522              .DO     VER<>495        ; (all versions except 4.95)
F8F9-86 50           523 ( 2)         LDA     #COLS
F8FB-                524              .FI
F8FB-                525      ;
F8FB-             S  526              .DO     VER=495         ; (version 4.95 only)
F8FB-             S  527              LDA     <$01
F8FB-                528              .FI
F8FB-                529      ;
F8FB-D6 8F           530 ( 4)         LDB     <CROW
F8FD-3D              531 (11)         MUL
F8FE-DB 90           532 ( 4)         ADDB    <CCOL
F900-89 00           533 ( 2)         ADCA    #0
F902-D3 91           534 ( 6)         ADDD    <CPAGE
F904-39              535 ( 5)         RTS
F905-                536      ;
F905-                537      ; Calculate real address of cursor in memory space, result returned in X.
F905-                538      ;
F905-34 06           539 ( 7) CCLOCN: PSHS    D
F907-8D F0           540 ( 7)         BSR     CCOFST          ; Apparent address.
F909-84 07           541 ( 2)         ANDA    #WRPMSK         ; Wrap around in 1K or 2K page
F90B-C3 F0 00        542 ( 4)         ADDD    #VPAGE          ; Add start of video page
F90E-1F 01           543 ( 7)         TFR     D,X
F910-35 86           544 ( 9)         PULS    D,PC            ; Un-save and return
F912-                545      ;
F912-                546      ; Initialise Versatile Interface Adapter (VIA)
F912-                547      ;
F912-CC EF D0        548 ( 3) VIAI:   LDD     #IKPCR*256+IKIER
F915-8E E9 80        549 ( 3)         LDX     #KVIA           ; Point to VIA.
F918-A7 0C           550 ( 6)         STA     KPCR-KVIA,X     ; Peripheral control register
F91A-E7 0E           551 ( 6)         STB     KIER-KVIA,X     ; Interrupt enable register
F91C-86 7F           552 ( 2)         LDA     #$7F            ; Printer output (7 bits) plus
F91E-A7 03           553 ( 6)         STA     KDDRA-KVIA,X    ; cassette input on a side
F920-A6 0D           554 ( 6)         LDA     KIFR-KVIA,X     ; Cancel any interrupts present
F922-A7 0D           555 ( 6)         STA     KIFR-KVIA,X
F924-39              556 ( 5)         RTS
F925-                557      ;
F925-                558      ; Initialise CRT controller on VDU card, R or S version
F925-                559      ;
F925-                560      CRTCI:
F925-                561      ;
F925-                562              .DO     VER<>495        ; (all versions except 4.95)
F925-8E FF 0D        563 ( 3)         LDX     #CRTCSV         ; Table for S version
F928-                564              .FI
F928-                565      ;
F928-             S  566              .DO     VER=495         ; (version 4.95 only)
F928-             S  567              LDX     #$E300
F928-                568              .FI
F928-                569      ;
F928-CC 0D AA        570 ( 3)         LDD     #PAGHI+1*256+$AA ; Test the page register
F92B-FD E8 40        571 ( 6)         STD     CRTC            ; (low byte) for read/write ability
F92E-F1 E8 41        572 ( 5)         CMPB    CRTC+1
F931-27 02           573 ( 3)         BEQ     CRTC11          ; If so, then V version
F933-30 0C           574 ( 1)         LEAX    $C,X            ; 'LEAX CRTCRV-CRTCSV,X'        ; else get R table instead
F935-86 0B           575 ( 2) CRTC11: LDA     #12-1           ; Set up 12 registers
F937-E6 86           576 ( 6) CRTC12: LDB     A,X             ; Get data and store it in correct register
F939-FD E8 40        577 ( 6)         STD     CRTC
F93C-4A              578 ( 2)         DECA
F93D-2A F8           579 ( 3)         BPL     CRTC12          ; Repeat until all 12 done
F93F-                580      ;
F93F-                581      ; Reset display to a blank page with cursor at top left of screen
F93F-                582      ;
F93F-0F 8F           583 ( 6) CLRALL: CLR     <CROW           ; Row 0
F941-0F 90           584 ( 6)         CLR     <CCOL           ; Column 0
F943-0F 91           585 ( 6)         CLR     <CPAGE+0        ; Current page set
F945-0F 92           586 ( 6)         CLR     <CPAGE+1        ; to start of display memory
F947-17 00 9C        587 ( 9)         LBSR    SETTOP          ; Set page in CRTC chip
F94A-17 00 A1        588 ( 9)         LBSR    SETCUR          ; and set cursor in CRTC chip
F94D-                589      ;
F94D-                590      ; Clear the display memory to all blanks
F94D-                591      ;
F94D-CC 20 20        592 ( 3) CLRSCN: LDD     #SPACE*256+SPACE ; Two spaces
F950-8E F0 00        593 ( 3)         LDX     #VPAGE          ; Start of display memory
F953-ED 81           594 ( 9) CLRS1:  STD     ,X++            ; Store two blanks
F955-8C F8 00        595 ( 4)         CMPX    #VPAGE+PSIZE    ; and repeat
F958-26 F9           596 ( 3)         BNE     CLRS1           ; until done all page
F95A-39              597 ( 5)         RTS
F95B-                598      ;
F95B-                599      ; This routine used to put a character to the VDU, handling CR, LF, backspace and form feed.
F95B-                600      ; All registers are saved.
F95B-                601      ;
F95B-34 7F           602 (15) DISPLA: PSHS    U,Y,X,DP,B,A,CC ; Save registers
F95D-C6 E3           603 ( 2)         LDB     #MONDP
F95F-1F 9B           604 ( 7)         TFR     B,DP
F961-9E 6F           605 ( 5)         LDX     <FUNCTI         ; Get function table
F963-1A 10           606 ( 3)         ORCC    #IRQ            ; Stop interrupts since not re-entrant
F965-8D 3F           607 ( 7)         BSR     DISPCH          ; Jump on function table
F967-35 FF           608 (17)         PULS    U,Y,X,DP,B,A,CC,PC      ; then restore and return
F969-                609      ;
F969-                610      ; This routine puts a character on display and moves cursor
F969-                611      ;
F969-8D 9A           612 ( 7) SIMCHR: BSR     CCLOCN          ; Find location in memory
F96B-A7 84           613 ( 5)         STA     ,X              ; and store character
F96D-0C 90           614 ( 6)         INC     <CCOL           ; move cursor across
F96F-96 90           615 ( 4)         LDA     <CCOL           ; then done if
F971-                616      ;
F971-                617              .DO     VER<>495        ; (all versions except 4.95)
F971-81 50           618 ( 2)         CMPA    #COLS           ; all columns
F973-                619              .FI
F973-                620      ;
F973-             S  621              .DO     VER=495         ; (version 4.95 only)
F973-             S  622              CMPA    <$01
F973-                623              .FI
F973-                624      ;
F973-26 0E           625 ( 3)         BNE     SIM1            ; not yet filled
F975-0F 90           626 ( 6)         CLR     <CCOL           ; Do CR
F977-                627      ;
F977-                628      ; Move cursor down one line, scroll display if required
F977-                629      ;
F977-0C 8F           630 ( 6) DOLF:   INC     <CROW           ; Down a row
F979-96 8F           631 ( 4)         LDA     <CROW
F97B-                632      ;
F97B-                633              .DO     VER<>495        ; (all versions except 4.95)
F97B-81 19           634 ( 2)         CMPA    #ROWS           ; Last row yet
F97D-                635              .FI
F97D-                636      ;
F97D-             S  637              .DO     VER=495         ; (version 4.95 only)
F97D-             S  638              CMPA    <$06
F97D-                639              .FI
F97D-                640      ;
F97D-26 04           641 ( 3)         BNE     SIM1            ; if not then done,
F97F-0A 8F           642 ( 6)         DEC     <CROW           ; else back up
F981-8D 40           643 ( 7)         BSR     SCROLL          ; and scroll instead
F983-20 69           644 ( 3) SIM1:   BRA     SETCUR          ; then set new cursor
F985-                645      ;
F985-                646      ; Move cursor back erasing last character.
F985-                647      ;
F985-8D 08           648 ( 7) DORUB:  BSR     BSONE           ; Back up cursor
F987-86 20           649 ( 2)         LDA     #SPACE
F989-8D D0           650 ( 7)         BSR     DISPLA          ; then blank last character,
F98B-8D 02           651 ( 7)         BSR     BSONE           ; and back up again
F98D-20 5F           652 ( 3) LF98D:  BRA     SETCUR          ; then set cursor up
F98F-                653      ;
F98F-                654      ; Back cursor up allowing line and row underflow.
F98F-                655      ;
F98F-0A 90           656 ( 6) BSONE:  DEC     <CCOL           ; Left move cursor
F991-2A 0C           657 ( 3)         BPL     BS1             ; No under flow
F993-                658      ;
F993-                659              .DO     VER<>495        ; (all versions except 4.95)
F993-86 4F           660 ( 2)         LDA     #COLS-1         ; else set to
F995-                661              .FI
F995-                662      ;
F995-             S  663              .DO     VER=495         ; (version 4.95 only)
F995-             S  664              LDA     <$0C
F995-                665              .FI
F995-                666      ;
F995-97 90           667 ( 4)         STA     <CCOL           ; right margin
F997-0A 8F           668 ( 6)         DEC     <CROW           ; and up one row
F999-2A 04           669 ( 3)         BPL     BS1             ; No row underflow
F99B-0F 8F           670 ( 6)         CLR     <CROW
F99D-0F 90           671 ( 6)         CLR     <CCOL
F99F-39              672 ( 5) BS1:    RTS
F9A0-                673      ;
F9A0-                674      ; Dispatch routine looks up a character in a table,
F9A0-                675      ; character in A, table address ,X
F9A0-                676      ;
F9A0-                677      ; Table format is:      First byte, number of entries 1 to 255
F9A0-                678      ;
F9A0-                679      ;       Repeat for each entry:  character to match with,
F9A0-                680      ;                               2-byte offset from start of this table
F9A0-                681      ;                               of routine to jump to if characters match
F9A0-                682      ;
F9A0-                683      ;       flag byte:  control if no match found:
F9A0-                684      ;
F9A0-                685      ;       positive: next word is offset of default routine
F9A0-                686      ;       zero:     return to calling program
F9A0-                687      ;       negative: next word is address of another table to search
F9A0-                688      ;
F9A0-EC 84           689 ( 6) DIS2:   LDD     ,X              ; Get address of new table,
F9A2-ED 62           690 ( 7)         STD     2,S             ; replace old on stack,
F9A4-35 56           691 (11)         PULS    D,X,U           ; and begin again
F9A6-34 56           692 (11) DISPCH: PSHS    D,X,U           ; Save registers
F9A8-E6 81           693 ( 8)         LDB     ,X++            ; Get length and move to offset.
F9AA-A1 1F           694 ( 6) DIS1:   CMPA    -1,X            ; Compare characters
F9AC-27 0B           695 ( 3)         BEQ     DIS3            ; Found it, else,
F9AE-30 03           696 ( 1)         LEAX    3,X             ; move down.
F9B0-5A              697 ( 2)         DECB                    ; Repeat until
F9B1-26 F7           698 ( 3)         BNE     DIS1            ; done
F9B3-6D 1F           699 ( 8)         TST     -1,X            ; Test flag byte.
F9B5-27 0A           700 ( 3)         BEQ     DIS4            ; Zero means return
F9B7-2B E7           701 ( 3)         BMI     DIS2            ; search new table, else
F9B9-EC 84           702 ( 6) DIS3:   LDD     ,X              ; get offset and
F9BB-E3 62           703 ( 8)         ADDD    2,S             ; add start of table, then
F9BD-ED 64           704 ( 7)         STD     4,S             ; store in stack.
F9BF-35 96           705 (11)         PULS    D,X,PC          ; Restore and go to routine
F9C1-35 D6           706 (13) DIS4:   PULS    D,X,U,PC        ; Return to caller
F9C3-                707      ;
F9C3-                708      ; Scroll the display up one line, leave cursor at same position on screen, leave registers intact
F9C3-                709      ;
F9C3-DC 91           710 ( 5) SCROLL: LDD     <CPAGE          ; Get start of page
F9C5-C3 07 D0        711 ( 4)         ADDD    #ROWS*COLS      ; then move off end, $03E8 (40-column) or $07D0 (80-column)
F9C8-8E F0 00        712 ( 3)         LDX     #VPAGE          ; Actual memory address
F9CB-CE 20 20        713 ( 3)         LDU     #SPACE*256+SPACE ; Double space
F9CE-                714      ;
F9CE-                715              .DO     VER<>495        ; (all versions except 4.95)
F9CE-10 8E 00 28     716 ( 4)         LDY     #COLS/2         ; Number to blank
F9D2-                717              .FI
F9D2-                718      ;
F9D2-             S  719              .DO     VER=495         ; (version 4.95 only)
F9D2-             S  720              LDY     <$0D
F9D2-             S  721              NOP
F9D2-                722              .FI
F9D2-                723      ;
F9D2-84 07           724 ( 2) SCR1:   ANDA    #WRPMSK         ; Wrap around in 1K or 2K
F9D4-EF 8B           725 (10)         STU     D,X             ; and put 2 blanks
F9D6-C3 00 02        726 ( 4)         ADDD    #2              ; Move up and
F9D9-31 3F           727 ( 1)         LEAY    -1,Y            ; repeat until
F9DB-26 F5           728 ( 3)         BNE     SCR1            ; line done
F9DD-83 07 D0        729 ( 4)         SUBD    #ROWS*COLS      ; Move to second line now, $03E8 (40-column) or $07D0 (80-column)
F9E0-84 07           730 ( 2)         ANDA    #WRPMSK         ; wrap around and
F9E2-DD 91           731 ( 5)         STD     <CPAGE          ; set as new page
F9E4-8D 08           732 ( 7)         BSR     SETCUR          ; Put cursor back in position
F9E6-                733      ;
F9E6-                734      ; Put page address into CRT controller.
F9E6-                735      ;
F9E6-9E 91           736 ( 5) SETTOP: LDX     <CPAGE          ; Get page
F9E8-86 0C           737 ( 2)         LDA     #PAGHI          ; Point to page start register
F9EA-20 09           738 ( 3)         BRA     SETPAR          ; then enter parameters
F9EC-                739      ;
F9EC-                740      ; Do a carriage return by setting column to 0
F9EC-                741      ;
F9EC-0F 90           742 ( 6) DOCR:   CLR     <CCOL
F9EE-                743      ;
F9EE-                744      ; Set cursor register in CRT controller.
F9EE-                745      ;
F9EE-17 FF 08        746 ( 9) SETCUR: LBSR    CCOFST          ; Get cursor address, no wrap around
F9F1-1F 01           747 ( 7)         TFR     D,X             ; into X
F9F3-86 0E           748 ( 2)         LDA     #CURHI          ; Point to cursor register
F9F5-                749      ;
F9F5-                750      ; Put 2 byte value into CRT controller, value in X, high byte register number in A
F9F5-                751      ;
F9F5-34 10           752 ( 7) SETPAR: PSHS    X               ; Get high byte
F9F7-35 04           753 ( 6)         PULS    B               ; Set register
F9F9-FD E8 40        754 ( 6)         STD     CRTC            ; and data move to low byte
F9FC-4C              755 ( 2)         INCA                    ; Get low byte
F9FD-35 04           756 ( 6)         PULS    B               ; Set register
F9FF-FD E8 40        757 ( 6)         STD     CRTC            ; and data.
FA02-39              758 ( 5)         RTS
FA03-                759      ;
FA03-                760      ; This routine puts keyboard input into line buffer
FA03-                761      ; If no room then ignores character, else echoes to display
FA03-                762      ; If echo is switched on handles rubout unless line buffer is switched off
FA03-                763      ;
FA03-D6 60           764 ( 4) HAVCHR: LDB     <ECHOF
FA05-2A 04           765 ( 3)         BPL     HAV3            ; Buffer off, so no rubout
FA07-81 7F           766 ( 2)         CMPA    #RUBCH
FA09-27 23           767 ( 3)         BEQ     BSP1            ; Go do rubout
FA0B-8D 37           768 ( 7) HAV3:   BSR     PUTCHR          ; Put into buffer
FA0D-27 43           769 ( 3)         BEQ     PUT1            ; No room, do not echo
FA0F-5D              770 ( 2)         TSTB                    ; If buffer off, then no
FA10-2A 08           771 ( 3)         BPL     HAV4            ; line feed on CR input
FA12-81 0D           772 ( 2)         CMPA    #CR
FA14-26 06           773 ( 3)         BNE     KBECHO          ; Not CR, so no
FA16-8D 04           774 ( 7)         BSR     KBECHO          ; echo of a linefeed
FA18-86 0A           775 ( 2)         LDA     #LF
FA1A-9F 87           776 ( 5) HAV4:   STX     <HEADST         ; Move static pointer up
FA1C-                777      ;
FA1C-                778      ; Put character in A to console output if echo on
FA1C-                779      ;
FA1C-D6 60           780 ( 4) KBECHO: LDB     <ECHOF          ; See if echo on
FA1E-58              781 ( 2)         LSLB                    ; Need bit 6
FA1F-2A 31           782 ( 3)         BPL     PUT1            ; Not on if zero
FA21-                783      ;
FA21-                784      ; Console output routine, sends to printer also if switched on
FA21-                785      ;
FA21-                786              .DP     0
FA21-7D E3 61        787 ( 7) CONOUT: TST     PFLAG           ; If printer off then
FA24-27 04           788 ( 3)         BEQ     CANOP1          ; value is zero
FA26-AD 9F E3 6D     789 (13)         JSR     [PRINT1]        ; else call printer
FA2A-6E 9F E3 65     790 ( 9) CANOP1: JMP     [COPADR]        ; then console output
FA2E-                791              .DP     MONDP
FA2E-9E 89           792 ( 5) BSP1:   LDX     <HEADDY         ; End of line, if at start of line
FA30-9C 87           793 ( 6)         CMPX    <HEADST
FA32-27 1E           794 ( 3)         BEQ     PUT1            ; then nothing to rubout
FA34-8C E3 AE        795 ( 4)         CMPX    #BUFFER         ; Do cyclic
FA37-26 03           796 ( 3)         BNE     BSP2
FA39-30 88 52        797 ( 1)         LEAX    BUFLEN,x        ; decrement of pointer
FA3C-30 1F           798 ( 1) BSP2:   LEAX    -1,x
FA3E-9F 89           799 ( 5)         STX     <HEADDY         ; Set new end of line
FA40-96 5F           800 ( 4)         LDA     <BSECHO         ; and echo a backspace
FA42-20 D8           801 ( 3)         BRA     KBECHO
FA44-                802      ;
FA44-                803      ; Put character into buffer if room, return Z=0, else return Z=1
FA44-                804      ;
FA44-9E 89           805 ( 5) PUTCHR: LDX     <HEADDY         ; Get pointer
FA46-8D 0B           806 ( 7)         BSR     BUMPU           ; If no room, then
FA48-9C 8B           807 ( 6)         CMPX    <TAIL           ; pointers equal,
FA4A-27 06           808 ( 3)         BEQ     PUT1            ; so done
FA4C-A7 84           809 ( 5)         STA     ,X              ; Store it and
FA4E-9F 89           810 ( 5)         STX     <HEADDY         ; set new pointer
FA50-1C FB           811 ( 3)         ANDCC   #255-ZERO       ; Clear Z flag
FA52-39              812 ( 5) PUT1:   RTS
FA53-                813      ;
FA53-                814      ; Cyclic increment of buffer pointers.
FA53-                815      ;
FA53-30 01           816 ( 1) BUMPU:  LEAX    1,X
FA55-8C E4 00        817 ( 4)         CMPX    #BUFFER+BUFLEN
FA58-26 03           818 ( 3)         BNE     ANRTS
FA5A-8E E3 AE        819 ( 3)         LDX     #BUFFER
FA5D-39              820 ( 5) ANRTS:  RTS
FA5E-                821      ;
FA5E-                822      ; Get character from buffer, if none then clears interrupt
FA5E-                823      ; mask and waits. all registers saved, including CC
FA5E-                824      ;
FA5E-                825              .DP     0
FA5E-34 11           826 ( 8) GETCHR: PSHS    X,CC            ; Save and
FA60-20 02           827 ( 3)         BRA     GETCH1          ; skip wait
FA62-3C EF           828 (20) GETCH2: CWAI    #255-IRQ        ; Wait for an interrupt
FA64-BE E3 8B        829 ( 6) GETCH1: LDX     TAIL            ; Get tail pointer
FA67-BC E3 87        830 ( 7)         CMPX    HEADST          ; If equals static head
FA6A-27 F6           831 ( 3)         BEQ     GETCH2          ; then no character
FA6C-8D E5           832 ( 7)         BSR     BUMPU           ; else move up
FA6E-A6 84           833 ( 5)         LDA     ,X              ; and get it.
FA70-BF E3 8B        834 ( 6)         STX     TAIL            ; Set new tail
FA73-35 91           835 (10)         PULS    CC,X,PC
FA75-                836      ;
FA75-                837      ; Output X register as four hex digits to console, all registers saved
FA75-                838      ;
FA75-                839              .DP     0
FA75-34 06           840 ( 7) OPXREG: PSHS    D
FA77-1F 10           841 ( 7)         TFR     X,D
FA79-8D 06           842 ( 7)         BSR     OPAREG
FA7B-1F 98           843 ( 7)         TFR     B,A
FA7D-8D 18           844 ( 7)         BSR     OPARSP
FA7F-35 86           845 ( 9)         PULS    D,PC
FA81-                846      ;
FA81-                847      ; Output a register as two hex digits to console, all registers saved except a
FA81-                848      ;
FA81-34 02           849 ( 6) OPAREG: PSHS    A
FA83-44              850 ( 2)         LSRA
FA84-44              851 ( 2)         LSRA
FA85-44              852 ( 2)         LSRA
FA86-44              853 ( 2)         LSRA
FA87-8D 04           854 ( 7)         BSR     HEXOUT          ; Left nibble
FA89-A6 E0           855 ( 7)         LDA     ,S+             ; Get byte back and
FA8B-84 0F           856 ( 2)         ANDA    #15             ; do right nibble
FA8D-                857      ;
FA8D-                858      ; Output A as a single hex digit.
FA8D-                859      ;
FA8D-8B 30           860 ( 2) HEXOUT: ADDA    #'0'
FA8F-81 39           861 ( 2)         CMPA    #'9'
FA91-23 02           862 ( 3)         BLS     HEX2
FA93-8B 07           863 ( 2)         ADDA    #'A'-'9'-1
FA95-20 8A           864 ( 3) HEX2:   BRA     CONOUT          ; Output and return
FA97-                865      ;
FA97-                866      ; Output a hex digit followed by a space
FA97-                867      ;
FA97-8D E8           868 ( 7) OPARSP: BSR     OPAREG
FA99-86 20           869 ( 2)         LDA     #SPACE
FA9B-20 F8           870 ( 3)         BRA     HEX2
FA9D-                871      ;
FA9D-                872      ; Printer routine, this interfaces to Anadex or Centronics parallel interface printers
FA9D-                873      ;
FA9D-                874              .DP     0
FA9D-34 46           875 ( 9) PRINT:  PSHS    D,U
FA9F-CE E9 80        876 ( 3)         LDU     #KVIA           ; Point to VIA
FAA2-B1 E3 62        877 ( 5)         CMPA    PNEW            ; If spec'd symbol then
FAA5-27 0E           878 ( 3)         BEQ     PEXIT           ; do not send
FAA7-E6 4F           879 ( 6) PWAIT1: LDB     KORA2-KVIA,U    ; Check if busy
FAA9-2B FC           880 ( 3)         BMI     PWAIT1          ; If so then wait
FAAB-A7 41           881 ( 6)         STA     KORA-KVIA,U     ; Store data
FAAD-C6 ED           882 ( 2)         LDB     #IKPCR-PSTRB    ; then low strobe
FAAF-E7 4C           883 ( 6)         STB     KPCR-KVIA,U
FAB1-C6 EF           884 ( 2)         LDB     #IKPCR          ; and high strobe
FAB3-E7 4C           885 ( 6)         STB     KPCR-KVIA,U
FAB5-35 C6           886 (11) PEXIT:  PULS    PC,U,B,A        ; Pull registers and return
FAB7-                887      ;
FAB7-                888      ; These tables are the decision tables for the memory examine and change function
FAB7-                889      ;
FAB7-                890              .DP     MONDP
FAB7-08              891      MTABA:  .DB     MTABAE-MTABA/3-1        ; number of entries
FAB8-56              892              .AS     'V'
FAB9-00 2C           893              .DW     VADDR-MTABA     ; Modify break address and memory
FABB-47              894              .AS     'G'
FABC-00 34           895              .DW     GADDR-MTABA     ; Modify go address and memory
FABE-50              896              .AS     'P'
FABF-00 3C           897              .DW     PADDR-MTABA     ; Modify proceed address and memory
FAC1-52              898              .AS     'R'
FAC2-00 42           899              .DW     RADDR-MTABA     ; Modify register locations
FAC4-20              900              .DB     SPACE
FAC5-00 51           901              .DW     SPACEA-MTABA
FAC7-2C              902              .DB     COMMA
FAC8-00 7A           903              .DW     COMMAA-MTABA
FACA-3B              904              .DB     SEMIC
FACB-00 8A           905              .DW     SEMICA-MTABA
FACD-2D              906              .DB     MINUS
FACE-00 8E           907              .DW     MINUSA-MTABA
FAD0-01              908              .DB     1
FAD1-00 71           909              .DW     NOTA-MTABA
FAD3-                910      MTABAE: .EQ     $
FAD3-                911      ;
FAD3-04              912      MTABB:  .DB     MTABBE-MTABB/3-1
FAD4-20              913              .DB     SPACE
FAD5-00 5E           914              .DW     SPACEB-MTABB
FAD7-2C              915              .DB     COMMA
FAD8-00 8D           916              .DW     COMMAB-MTABB
FADA-3B              917              .DB     SEMIC
FADB-00 69           918              .DW     SEMICB-MTABB
FADD-2D              919              .DB     MINUS
FADE-00 72           920              .DW     MINUSB-MTABB
FAE0-01              921              .DB     1
FAE1-00 7B           922              .DW     NOTB-MTABB
FAE3-                923      MTABBE: .EQ     $
FAE3-                924      ;
FAE3-                925      ; Memory examine and change routine.
FAE3-                926      ;
FAE3-17 01 60        927 ( 9) VADDR:  LBSR    BRKOUT          ; Take out any break
FAE6-CE E3 A3        928 ( 3)         LDU     #CBREAK         ; point to break address store
FAE9-20 03           929 ( 3)         BRA     ADDR1
FAEB-CE E3 95        930 ( 3) GADDR:  LDU     #GSAV           ; point to go address store
FAEE-10 AE C4        931 ( 7) ADDR1:  LDY     ,U              ; Get initial value
FAF1-20 3E           932 ( 3)         BRA     GDATA
FAF3-DE AA           933 ( 5) PADDR:  LDU     <USRSTK
FAF5-33 4A           934 ( 1)         LEAU    $0A,U           ; Point to user PC
FAF7-20 F5           935 ( 3)         BRA     ADDR1
FAF9-10 9E AA        936 ( 6) RADDR:  LDY     <USRSTK         ; Get address off 'CC' register
FAFC-CE E3 AC        937 ( 3) RADDR1: LDU     #TEMP           ; Dummy location for new value
FAFF-20 30           938 ( 3)         BRA     GDATA
FB01-CE E3 93        939 ( 3) MEM:    LDU     #MSAV           ; Point to memory address store
FB04-10 AE C4        940 ( 7)         LDY     ,U              ; Get initial value
FB07-5F              941 ( 2)         CLRB                    ; Set status zero
FB08-17 FD 74        942 ( 9) SPACEA: LBSR    CONCHR          ; Get input
FB0B-27 0B           943 ( 3)         BEQ     CRA             ; No address given
FB0D-8E FA B7        944 ( 3)         LDX     #MTABA          ; Search address table
FB10-16 FE 93        945 (55)         LBRA    DISPCH
FB13-5D              946 ( 2) CRD:    TSTB                    ; If status
FB14-2F 02           947 ( 3)         BLE     CRA             ; -1 or 0 then no change
FB16-31 21           948 ( 1)         LEAY    $01,Y           ; else up one
FB18-1F 21           949 ( 7) CRA:    TFR     Y,X             ; Print out address
FB1A-17 FF 58        950 ( 9)         LBSR    OPXREG
FB1D-A6 84           951 ( 5)         LDA     ,X              ; then data
FB1F-17 FF 75        952 ( 9)         LBSR    OPARSP
FB22-C6 01           953 ( 2)         LDB     #$01            ; Set status +1
FB24-D7 A1           954 ( 4)         STB     <ONLINE         ; Allow next line
FB26-20 09           955 ( 3)         BRA     GDATA           ; and continue
FB28-97 A2           956 ( 4) NOTA:   STA     <LASTC          ; Save for re-use
FB2A-8D 40           957 ( 7)         BSR     NUMB            ; Get number with
FB2C-29 38           958 ( 3)         BVS     MERR            ; error if none
FB2E-1F 02           959 ( 7)         TFR     D,Y             ; is new address
FB30-5F              960 ( 2) DAT1:   CLRB                    ; Set status 0
FB31-                961      COMMAA: .EQ     $
FB31-                962      SPACEB: .EQ     $
FB31-17 FD 4B        963 ( 9) GDATA:  LBSR    CONCHR          ; Get input
FB34-27 DD           964 ( 3)         BEQ     CRD             ; No data found CR
FB36-8E FA D3        965 ( 3)         LDX     #MTABAE         ; else search data table
FB39-16 FE 6A        966 (55)         LBRA    DISPCH
FB3C-5D              967 ( 2) SEMICB: TSTB                    ; Test status
FB3D-2C 02           968 ( 3)         BGE     SEMICA          ; If -1 then
FB3F-31 3F           969 ( 1)         LEAY    -1,Y            ; dec before
FB41-10 AF C4        970 ( 7) SEMICA: STY     ,U              ; Save new address
FB44-39              971 ( 5)         RTS                     ; and exit
FB45-                972      MINUSA: .EQ     $
FB45-31 3F           973 ( 1) MINUSB: LEAY    -1,Y            ; Back down 1,
FB47-5D              974 ( 2)         TSTB                    ; but if status
FB48-2C 02           975 ( 3)         BGE     MIND2           ; is -1 then
FB4A-31 3F           976 ( 1)         LEAY    -1,Y            ; duck down 2
FB4C-20 E2           977 ( 3) MIND2:  BRA     DAT1            ; then continue
FB4E-97 A2           978 ( 4) NOTB:   STA     <LASTC          ; Save for re-use
FB50-8D 1A           979 ( 7)         BSR     NUMB            ; in number.
FB52-29 12           980 ( 3)         BVS     MERR            ; Should have number
FB54-E7 A4           981 ( 5)         STB     ,Y              ; Store data then
FB56-E1 A4           982 ( 5)         CMPB    ,Y              ; check it
FB58-27 06           983 ( 3)         BEQ     COMMAB          ; is ok,
FB5A-8E FF 8F        984 ( 3)         LDX     #MQRY           ; else tell
FB5D-17 FD 8C        985 ( 9)         LBSR    STRING          ; user.
FB60-31 21           986 ( 1) COMMAB: LEAY    1,Y             ; Go up 1
FB62-C6 FF           987 ( 2)         LDB     #$FF            ; with status -1
FB64-20 CB           988 ( 3)         BRA     GDATA           ; then continue
FB66-17 FD 16        989 ( 9) MERR:   LBSR    CONCHR          ; Get wrong symbol
FB69-16 01 1D        990 (55)         LBRA    BADCMD          ; and tell user
FB6C-                991      ;
FB6C-                992      ; Get hex number from input stream, allow leading spaces and stop on first non-hex character,
FB6C-                993      ; return number in D, with V=0, if no number then do and V=1
FB6C-                994      ;
FB6C-                995              .DP     0
FB6C-4F              996 ( 2) NUMB:   CLRA
FB6D-5F              997 ( 2)         CLRB
FB6E-34 06           998 ( 7)         PSHS    D               ; Put initial zero value
FB70-8D 18           999 ( 7)         BSR     GETHXS          ; Get first non-blank as hex value
FB72-29 14          1000 ( 3)         BVS     NUMB1           ; wasn't hex
FB74-C6 04          1001 ( 2) NUMB3:  LDB     #$04
FB76-48             1002 ( 2)         ASLA                    ; Move to
FB77-48             1003 ( 2)         ASLA
FB78-48             1004 ( 2)         ASLA
FB79-48             1005 ( 2)         ASLA                    ; high nibble
FB7A-48             1006 ( 2) NUMB2:  ASLA                    ; Rotate into
FB7B-69 61          1007 ( 8)         ROL     1,S
FB7D-               1008      ;
FB7D-             S 1009              .DO     VER=490         ; (original Acorn version 4.90 only)
FB7D-             S 1010              .DB     $69,$60         ; 'ROL  0,S'
FB7D-               1011              .FI
FB7D-               1012      ;
FB7D-               1013              .DO     VER<>490        ; (versions 492 and 495)
FB7D-69 E4          1014              .DB     $69,$E4         ; 'ROL ,S'
FB7F-               1015              .FI
FB7F-               1016      ;
FB7F-5A             1017 ( 2)         DECB                    ; Do 4 times.
FB80-26 F8          1018 ( 3)         BNE     NUMB2           ; Get a hex digit from console
FB82-8D 11          1019 ( 7)         BSR     GETHEX          ; Was hex so use,
FB84-28 EE          1020 ( 3)         BVC     NUMB3           ; else finish with V clear
FB86-1C FD          1021 ( 3) NUMB4:  ANDCC   #$FD            ; CLV
FB88-35 86          1022 ( 9) NUMB1:  PULS    D,PC
FB8A-               1023      ;
FB8A-               1024      ; GETHXS - get a hex digit ignoring leading spaces
FB8A-               1025      ; GETHEX - get a hex digit both return value in A with V=0 else set V=1 if non-hex
FB8A-               1026      ;
FB8A-17 FC F2       1027 ( 9) GETHXS: LBSR    CONCHR          ; Get input.
FB8D-27 22          1028 ( 3)         BEQ     GETH5           ; On CR, no number
FB8F-81 20          1029 ( 2)         CMPA    #SPACE          ; If space
FB91-27 F7          1030 ( 3)         BEQ     GETHXS          ; then ignore
FB93-20 05          1031 ( 3)         BRA     GETH2           ; Change to hex
FB95-               1032      ;
FB95-17 FC E7       1033 ( 9) GETHEX: LBSR    CONCHR          ; Get input
FB98-27 17          1034 ( 3)         BEQ     GETH5           ; On CR, no number
FB9A-81 30          1035 ( 2) GETH2:  CMPA    #'0'
FB9C-25 0C          1036 ( 3)         BCS     GETH1           ; Illegal hex
FB9E-81 39          1037 ( 2)         CMPA    #'9'
FBA0-23 14          1038 ( 3)         BLS     GETH3           ; Number hex
FBA2-81 41          1039 ( 2)         CMPA    #'A'
FBA4-25 04          1040 ( 3)         BCS     GETH1           ; Illegal hex
FBA6-81 46          1041 ( 2)         CMPA    #'F'
FBA8-23 0A          1042 ( 3)         BLS     GETH4           ; Alpha hex
FBAA-81 2C          1043 ( 2) GETH1:  CMPA    #COMMA
FBAC-27 03          1044 ( 3)         BEQ     GETH5           ; Absorb comma
FBAE-B7 E3 A2       1045 ( 5)         STA     LASTC           ; else re-use
FBB1-1A 02          1046 ( 3) GETH5:  ORCC    #$02            ; Bad hex, SEV
FBB3-39             1047 ( 5)         RTS
FBB4-80 07          1048 ( 2) GETH4:  SUBA    #7              ; Alpha offset
FBB6-80 30          1049 ( 2) GETH3:  SUBA    #'0'            ; Number offset
FBB8-39             1050 ( 5)         RTS                     ; with V clear
FBB9-               1051      ;
FBB9-               1052      ; Resume user program using stack as stands
FBB9-               1053      ;
FBB9-               1054              .DP     MONDP
FBB9-32 62          1055 ( 1) RESUME: LEAS    2,S             ; Strip return address
FBBB-8D AF          1056 ( 7)         BSR     NUMB            ; Get number or zero
FBBD-DD A5          1057 ( 5)         STD     <NBREAK         ; and set break ignore count
FBBF-8D 6C          1058 ( 7) RES2:   BSR     BRKIN           ; Insert breakpoints
FBC1-35 FF          1059 (17)                 PULS    PC,U,Y,X,DP,B,A,CC      ; and pull all user registers off stack
FBC3-               1060      ;
FBC3-               1061      ; Software interrupt handler, come here on breakpoint
FBC3-               1062      ; Either stops and displays registers or traces past breakpoint and resumes
FBC3-               1063      ;
FBC3-86 E3          1064 ( 2) SWIHAN: LDA     #MONDP          ; Set up
FBC5-1F 8B          1065 ( 7)         TFR     A,DP            ; direct page
FBC7-               1066              .DP     MONDP
FBC7-AE 6A          1067 ( 7)         LDX     10,S            ; back up
FBC9-30 1F          1068 ( 1)         LEAX    -1,X            ; user
FBCB-AF 6A          1069 ( 7)         STX     10,S            ; program counter
FBCD-8D 77          1070 ( 7)         BSR     BRKOUT          ; remove breakpoint
FBCF-9E A5          1071 ( 5)         LDX     <NBREAK         ; Get count.
FBD1-27 08          1072 ( 3)         BEQ     RES1            ; stop if zero, else
FBD3-30 1F          1073 ( 1)         LEAX    -1,X            ; decrement
FBD5-9F A5          1074 ( 5)         STX     <NBREAK         ; and restore
FBD7-8D 76          1075 ( 7)         BSR     TUSER1          ; Trace past break
FBD9-20 E4          1076 ( 3)         BRA     RES2            ; then resume again
FBDB-10 DF AA       1077 ( 6) RES1:   STS     <USRSTK
FBDE-17 FC D7       1078 ( 9)         LBSR    EXREG           ; display registers
FBE1-20 19          1079 ( 3)         BRA     BACK1           ; and stay in monitor
FBE3-               1080      ;
FBE3-               1081      ; Change number in X if one given in input stream, destroys D
FBE3-               1082      ;
FBE3-8D 87          1083 ( 7) NUMBX:  BSR     NUMB
FBE5-29 02          1084 ( 3)         BVS     NUMBX1          ; No number
FBE7-1F 01          1085 ( 7)         TFR     D,X
FBE9-39             1086 ( 5) NUMBX1: RTS
FBEA-               1087      ;
FBEA-               1088      ; User program returns here if RTS done.
FBEA-               1089      ;
FBEA-32 7E          1090 ( 1) BACK:   LEAS    -2,S            ; Make room for new return address
FBEC-34 FF          1091 (17)         PSHS    CC,A,B,DP,X,Y,U,PC      ; and save all user registers
FBEE-8E FB EA       1092 ( 3)         LDX     #BACK           ; Set return address
FBF1-AF 6C          1093 ( 7)         STX     12,S            ; again
FBF3-C6 E3          1094 ( 2)         LDB     #MONDP
FBF5-1F 9B          1095 ( 7)         TFR     B,DP
FBF7-8D 4D          1096 ( 7)         BSR     BRKOUT          ; Remove breakpoints
FBF9-10 DF AA       1097 ( 6)         STS     <USRSTK         ; Save user stack pointer
FBFC-1C EF          1098 ( 3) BACK1:  ANDCC   #$EF            ; CLI: enable interrupts
FBFE-16 FC 59       1099 (55)         LBRA    PARSE           ; and resume monitor functions
FC01-               1100      ;
FC01-               1101      ; Go to user program, optional address specified
FC01-               1102      ; The stack pointer is reset, but the register contents are maintained as listed by the command
FC01-               1103
FC01-0F A5          1104 ( 6) GOUSER: CLR     <NBREAK+0       ; Put zero in
FC03-0F A6          1105 ( 6)         CLR     <NBREAK+1       ; break count
FC05-DE 5B          1106 ( 5)         LDU     <ISTACK         ; Get pointer
FC07-8E FB EA       1107 ( 3)         LDX     #BACK           ; return address,
FC0A-AF C3          1108 ( 9)         STX     ,--U            ; pushed first
FC0C-C6 0D          1109 ( 2)         LDB     #11+2           ; 12 registers plus return.
FC0E-A6 E5          1110 ( 6) GO1:    LDA     B,S             ; Get value and
FC10-A7 C2          1111 ( 7)         STA     ,-U             ; push it
FC12-5A             1112 ( 2)         DECB
FC13-2A F9          1113 ( 3)         BPL     GO1             ; For all registers
FC15-32 42          1114 ( 1)         LEAS    2,U             ; new stack, ignore return address
FC17-9E 95          1115 ( 5)         LDX     <GSAV           ; Saved address
FC19-8D C8          1116 ( 7)         BSR     NUMBX           ; Change if given
FC1B-9F 95          1117 ( 5)         STX     <GSAV           ; and restore.
FC1D-AF 6A          1118 ( 7)         STX     10,S            ; Put as user PC
FC1F-8D 0C          1119 ( 7)         BSR     BRKIN           ; Insert breakpoint
FC21-35 FF          1120 (17)         PULS    CC,A,B,DP,X,Y,U,PC      ; and begin user program
FC23-               1121      ;
FC23-               1122      ; Change user breakpoint position.
FC23-               1123      ;
FC23-8D 21          1124 ( 7) BRKSET  BSR     BRKOUT          ; Ensure old is out
FC25-8E FF FF       1125 ( 3)         LDX     #$FFFF          ; value for no break
FC28-8D B9          1126 ( 7)         BSR     NUMBX           ; change if given
FC2A-9F A3          1127 ( 5)         STX     <CBREAK         ; and save.
FC2C-39             1128 ( 5)         RTS
FC2D-               1129      ;
FC2D-               1130      ; Put breakpoint in if one exists.
FC2D-               1131      ;
FC2D-8D 09          1132 ( 7) BRKIN:  BSR     BRKTST          ; See if exists
FC2F-27 06          1133 ( 3)         BEQ     BRK1            ; Already a SWI, so done
FC31-97 A7          1134 ( 4)         STA     <CINST          ; else save it
FC33-86 3F          1135 ( 2)         LDA     #SWIOP
FC35-A7 84          1136 ( 5)         STA     ,X              ; and insert a SWI instead
FC37-39             1137 ( 5) BRK1:   RTS
FC38-               1138      ;
FC38-               1139      ; Check break required, if not does RTS twice.
FC38-               1140      ;
FC38-9E A3          1141 ( 5) BRKTST: LDX     <CBREAK         ; Get address
FC3A-8C FF FF       1142 ( 4)         CMPX    #$FFFF          ; $FFFF means none
FC3D-27 05          1143 ( 3)         BEQ     BRK10           ; not one
FC3F-A6 84          1144 ( 5)         LDA     ,X              ; Get instruction
FC41-81 3F          1145 ( 2)         CMPA    #SWIOP          ; see if SWI
FC43-39             1146 ( 5)         RTS                     ; then exit
FC44-35 90          1147 ( 9) BRK10:  PULS    PC,X            ; Exit twice
FC46-               1148      ;
FC46-               1149      ; Called by SWI
FC46-               1150      ; -------------
FC46-               1151      ; Remove a breakpoint if one present in code
FC46-               1152      ;
FC46-8D F0          1153 ( 7) BRKOUT: BSR     BRKTST          ; See if exists
FC48-26 04          1154 ( 3)         BNE     BRK2            ; Not SWI, leave alone
FC4A-96 A7          1155 ( 4)         LDA     <CINST          ; Get saved instruction
FC4C-A7 84          1156 ( 5)         STA     ,X              ; and restore in code
FC4E-39             1157 ( 5) BRK2:   RTS
FC4F-               1158      ;
FC4F-               1159      ; Trace one instruction of user code
FC4F-               1160      ;
FC4F-35 10          1161 ( 7) TUSER1: PULS    X               ; Get return address
FC51-9F 73          1162 ( 5)         STX     <IRQRTS         ; and save it
FC53-86 EF          1163 ( 2)         LDA     #255-IRQ        ; Clear IRQ mask
FC55-A4 E4          1164 ( 5)         ANDA    ,S              ; in user
FC57-A7 E4          1165 ( 5)         STA     ,S              ; condition codes
FC59-CC 0F 00       1166 ( 3)         LDD     #INTDEL         ; Delay before interrupt
FC5C-FD E9 84       1167 ( 6)         STD     KT1CL           ; Set timer going,
FC5F-35 FF          1168 (17)         PULS    CC,A,B,DP,X,Y,U,PC      ; start user program running
FC61-               1169      ;
FC61-               1170      ; Set number of instructions to trace on each command
FC61-               1171      ;
FC61-17 FF 08       1172 ( 9) TRACEN: LBSR    NUMB            ; Get 0 if no number
FC64-DD 5D          1173 ( 5)         STD     <NTRACE         ; Save result.
FC66-39             1174 ( 5) TRACE1: RTS
FC67-               1175      ;
FC67-               1176      ; Trace required number of instructions then display register contents and halt user
FC67-               1177      ;
FC67-9E 5D          1178 ( 5) TRACE:  LDX     <NTRACE         ; Get number to trace
FC69-27 FB          1179 ( 3)         BEQ     TRACE1          ; ignore command if zero
FC6B-32 62          1180 ( 1)         LEAS    2,S             ; strip return address
FC6D-9F A8          1181 ( 5) TRACE2: STX     <CTRACE         ; save number left
FC6F-8D DE          1182 ( 7)         BSR     TUSER1          ; trace one instruction
FC71-9E A8          1183 ( 5)         LDX     <CTRACE         ; Get number left
FC73-30 1F          1184 ( 1)         LEAX    -1,X            ; and decrement
FC75-26 F6          1185 ( 3)         BNE     TRACE2          ; repeat if required
FC77-16 FF 61       1186 (55)         LBRA    RES1            ; else show registers and halt user
FC7A-               1187      ;
FC7A-               1188      ; Turn printer echo of console output on or off
FC7A-               1189      ;
FC7A-17 FC 02       1190 ( 9) PCNTL:  LBSR    CONCHR          ; Get input
FC7D-27 06          1191 ( 3)         BEQ     POFF            ; if CR then off
FC7F-81 2B          1192 ( 2)         CMPA    #'+'            ; if plus
FC81-27 03          1193 ( 3)         BEQ     PON             ; then switch on
FC83-97 A2          1194 ( 4)         STA     <LASTC          ; Re-use if not +
FC85-4F             1195 ( 2) POFF:   CLRA                    ; Switch off value
FC86-97 61          1196 ( 4) PON:    STA     <PFLAG          ; Set flag
FC88-39             1197 ( 5)         RTS
FC89-               1198      ;
FC89-               1199      ; If get bad command, query it and ignore rest of line
FC89-               1200      ;
FC89-9E 75          1201 ( 5) BADCMD: LDX     <LINEPT         ; If memory input
FC8B-10 26 FC 18    1202 (5+)         LBNE    MEND            ; then exit
FC8F-8E FF C3       1203 ( 3)         LDX     #CQRY           ; Output query
FC92-17 FC 57       1204 ( 9)         LBSR    STRING          ; message
FC95-17 FD 89       1205 ( 9)         LBSR    CONOUT          ; and character
FC98-17 FC 4E       1206 ( 9)         LBSR    OPCRLF          ; followed by CR, LF
FC9B-17 FB E1       1207 ( 9) BAD1:   LBSR    CONCHR          ; Get input and
FC9E-26 FB          1208 ( 3)         BNE     BAD1            ; if not CR then ignore it
FCA0-39             1209 ( 5)         RTS                     ; then carry on
FCA1-               1210      ;
FCA1-               1211      ; Cassette file load routine, this searches for named file followed by data
FCA1-               1212      ;
FCA1-17 00 D1       1213 ( 9) LOAD:   LBSR    NAMEIN          ; Get file name
FCA4-17 FE C5       1214 ( 9)         LBSR    NUMB            ; Get offset
FCA7-DD 85          1215 ( 5)         STD     <OFFSET         ; and save
FCA9-8E E3 97       1216 ( 3) LOAD2:  LDX     #NAME           ; Point to filename space
FCAC-86 30          1217 ( 2) LOAD4:  LDA     #'0'            ; Get name file
FCAE-8D 4E          1218 ( 7)         BSR     GETHDR          ; header.
FCB0-26 FA          1219 ( 3)         BNE     LOAD4           ; Ignore others
FCB2-C6 06          1220 ( 2)         LDB     #$06            ; Name length
FCB4-D7 AC          1221 ( 4)         STB     <TEMP           ; Save it
FCB6-8D 66          1222 ( 7) LOAD3:  BSR     CBIN1           ; Get input character
FCB8-E6 80          1223 ( 7)         LDB     ,X+             ; and name character
FCBA-C1 3F          1224 ( 2)         CMPB    #'?'            ; If wildcard
FCBC-27 04          1225 ( 3)         BEQ     LOAD1           ; then matches
FCBE-A1 1F          1226 ( 6)         CMPA    -1,X            ; else compare
FCC0-26 E7          1227 ( 3)         BNE     LOAD2           ; Wrong name
FCC2-0A AC          1228 ( 6) LOAD1:  DEC     <TEMP           ; Count name length
FCC4-26 F0          1229 ( 3)         BNE     LOAD3           ; Repeat for all 6
FCC6-8D 56          1230 ( 7)         BSR     CBIN1           ; Ignore checksum byte
FCC8-               1231      ;
FCC8-               1232      ; Enter here for match without filename check
FCC8-               1233      ;
FCC8-86 31          1234 ( 2) LOAD7:  LDA     #'1'            ; Get data
FCCA-8D 32          1235 ( 7)         BSR     GETHDR          ; header
FCCC-26 24          1236 ( 3)         BNE     LOAD5           ; Wrong header
FCCE-8D 43          1237 ( 7)         BSR     CBIN2           ; Get start address
FCD0-1F 01          1238 ( 7)         TFR     D,X             ; and save while
FCD2-8D 3F          1239 ( 7)         BSR     CBIN2           ; getting end address
FCD4-34 06          1240 ( 7)                 PSHS    D       ; Put end on stack
FCD6-8D 46          1241 ( 7) LOAD6:  BSR     CBIN1           ; Get data item
FCD8-A7 80          1242 ( 7)         STA     ,X+             ; and store it
FCDA-AC E4          1243 ( 7)         CMPX    ,S              ; if not done
FCDC-23 F8          1244 ( 3)         BLS     LOAD6           ; then repeat
FCDE-8D 3E          1245 ( 7)         BSR     CBIN1           ; Get checksum byte
FCE0-35 10          1246 ( 7)         PULS    X               ; Get old end address
FCE2-17 FD 90       1247 ( 9)         LBSR    OPXREG          ; Show address so far
FCE5-1F 30          1248 ( 7)         TFR     U,D             ; check summed in U
FCE7-53             1249 ( 2)         COMB                    ; lower byte only
FCE8-27 DE          1250 ( 3)         BEQ     LOAD7           ; If ok, then repeat
FCEA-8E FF CD       1251 ( 3) LFCEA:  LDX     #LQRY           ; else message
FCED-17 FB FC       1252 ( 9)         LBSR    STRING          ; output
FCF0-20 04          1253 ( 3)         BRA     LKEYON
FCF2-81 39          1254 ( 2) LOAD5:  CMPA    #'9'            ; if not '9' then ignore
FCF4-26 D2          1255 ( 3)         BNE     LOAD7
FCF6-86 90          1256 ( 2) LKEYON: LDA     #CB1FLG+$80     ; Turn on keyboard
FCF8-B7 E9 8E       1257 ( 5)         STA     KIER
FCFB-16 FB EB       1258 (55)         LBRA    OPCRLF          ; then exit.
FCFE-               1259      ;
FCFE-               1260      ; Get a header from the tape, if the expected one then set zero status,
FCFE-               1261      ; else return non-zero status.  Initialises the checksum in U to 0
FCFE-               1262      ;
FCFE-34 02          1263 ( 6) GETHDR: PSHS    A               ; Save character
FD00-86 10          1264 ( 2)         LDA     #CB1FLG         ; Turn off keyboard
FD02-B7 E9 8E       1265 ( 5)         STA     KIER
FD05-8D 17          1266 ( 7) GETHD1: BSR     CBIN1           ; Get from tape
FD07-81 D8          1267 ( 2)         CMPA    #'X'+$80        ; and if not 'X' header marker
FD09-26 FA          1268 ( 3)         BNE     GETHD1          ; then try again
FD0B-8D 11          1269 ( 7)         BSR     CBIN1           ; Get next character
FD0D-CE 00 00       1270 ( 3)         LDU     #$0             ; Set up checksum
FD10-A1 E0          1271 ( 7)         CMPA    ,S+             ; and compare with required
FD12-39             1272 ( 5)         RTS                     ; then return
FD13-               1273      ;
FD13-               1274      ; Get 2 bytes and form a 16-bit value in D.  Add offset since is address
FD13-               1275      ;
FD13-8D 09          1276 ( 7) CBIN2:  BSR     CBIN1           ; Get 1 byte
FD15-1F 89          1277 ( 7)         TFR     A,B             ; and save while
FD17-8D 05          1278 ( 7)         BSR     CBIN1           ; get second
FD19-1E 89          1279 ( 7)         EXG     A,B             ; Wrong order, swap over
FD1B-D3 85          1280 ( 6)         ADDD    <OFFSET         ; Move by offset
FD1D-39             1281 ( 5)         RTS
FD1E-               1282      ;
FD1E-               1283      ; Get 1 byte from tape, modifying checksum to suit
FD1E-               1284      ;
FD1E-AD 9F E3 6B    1285 (13) CBIN1:  JSR     [CASINA]        ; Get byte then
FD22-33 C6          1286 ( 1)         LEAU    A,U             ; add to checksum
FD24-39             1287 ( 5)         RTS
FD25-               1288      ;
FD25-               1289      ; Software asynchronous transmitter, outputs value in A as a start bit, 8 data bits,
FD25-               1290      ; 2 stop bits, at rate controlled by count in DELCNT
FD25-               1291      ;
FD25-34 17          1292 (10) MCASOP: PSHS    CC,D,X          ; Saves all registers
FD27-1A 50          1293 ( 3)         ORCC    #$50            ; SEIF, Keep timing
FD29-C6 0B          1294 ( 2)         LDB     #11             ; Total length
FD2B-34 04          1295 ( 6)         PSHS    B               ; Save on stack
FD2D-C6 CF          1296 ( 2)         LDB     #IKPCR-COPBIT   ; Low start bit
FD2F-43             1297 ( 2)         COMA                    ; Want data inverted
FD30-12             1298 ( 2) MCAS01: NOP                     ; Get timing
FD31-20 00          1299 ( 3) LFD31:  BRA     MCAS02          ; constant
FD33-6A E4          1300 ( 7) MCAS02: DEC     ,S              ; Bits counter
FD35-2B 0E          1301 ( 3)         BMI     MCAS03          ; All done
FD37-F7 E9 8C       1302 ( 5)         STB     KPCR            ; Put out, but
FD3A-8D 0D          1303 ( 7)         BSR     CWAIT           ; wait 1 bit time
FD3C-C4 DF          1304 ( 2)         ANDB    #255-COPBIT     ; Assume next is zero
FD3E-44             1305 ( 2)         LSRA                    ; Get next bit
FD3F-25 EF          1306 ( 3)         BCS     MCAS01          ; Do want zero
FD41-CA 20          1307 ( 2)         ORB     #COPBIT         ; else set bit
FD43-20 EE          1308 ( 3)         BRA     MCAS02          ; and loop round
FD45-32 61          1309 ( 1) MCAS03: LEAS    1,S             ; Remove counter
FD47-35 97          1310 (12)         PULS    CC,D,X,PC       ; and return
FD49-               1311      ;
FD49-               1312      ; CWAIT waits for 1-bit time, destroys X
FD49-               1313      ; HWAIT waits 1/2 bit time, also destroys X
FD49-               1314      ;
FD49-               1315              .DP     0
FD49-8D 00          1316 ( 7) CWAIT:  BSR     HWAIT           ; Do first half
FD4B-BE E3 63       1317 ( 6) HWAIT:  LDX     DELCNT          ; Get count required
FD4E-30 1F          1318 ( 1) HW1:    LEAX    -1,X            ; Decrement
FD50-26 FC          1319 ( 3)         BNE     HW1             ; while non-zero
FD52-39             1320 ( 5)         RTS
FD53-               1321      ;
FD53-               1322      ; Software asynchronous receiver, gets value into A
FD53-               1323      ; Saves all other registers, only gets 1 stop bit
FD53-               1324      ;
FD53-               1325              .DP     MONDP
FD53-               1326      ;
FD53-               1327              .DO     VER<>495        ; (all versions except 4.95)
FD53-34 14          1328 ( 8) MCASIN: PSHS    B,X
FD55-86 80          1329 ( 2)         LDA     #$80            ; Rotating counter
FD57-F6 E9 80       1330 ( 5) MCAS11: LDB     KIRB            ; Wait for start bit
FD5A-2B FB          1331 ( 3) LFD5A:  BMI     MCAS11
FD5C-8D ED          1332 ( 7)         BSR     HWAIT           ; Wait 1/2 bit time
FD5E-F6 E9 80       1333 ( 5)         LDB     KIRB            ; Recheck
FD61-               1334              .FI
FD61-               1335      ;
FD61-             S 1336              .DO     VER=495         ; (version 4.95 only)
FD61-             S 1337      MCASIN: STX     <$A3
FD61-             S 1338              ANDCC   #$EF
FD61-             S 1339      MCAS11: LDD     #MON
FD61-             S 1340              PSHS    A,B
FD61-             S 1341              JMP     BOOT
FD61-             S 1342              ADCB    ,X+
FD61-               1343              .FI
FD61-               1344      ;
FD61-2B F4          1345 ( 3)         BMI     MCAS11          ; start bit
FD63-8D E4          1346 ( 7) MCAS12: BSR     CWAIT           ; Wait whole bit time
FD65-F6 E9 80       1347 ( 5)         LDB     KIRB            ; and get input
FD68-AC E4          1348 ( 7)         CMPX    ,S              ; waste time to
FD6A-11 AC E4       1349 ( 8)         CMPS    ,S              ; match loop delays
FD6D-58             1350 ( 2)         LSLB                    ; Move bit to carry
FD6E-46             1351 ( 2)         RORA                    ; then into byte
FD6F-24 F2          1352 ( 3)         BCC     MCAS12          ; Repeat for 8 bits
FD71-8D D6          1353 ( 7)         BSR     CWAIT           ; Get into stop bit
FD73-35 94          1354 (10)         PULS    B,X,PC          ; and done
FD75-               1355      ;
FD75-               1356      ; Routine gets name from input stream, up to 6 characters long
FD75-               1357      ; No name leaves memory unaltered.  Any name is padded to 6 characters with spaces
FD75-               1358      ;
FD75-8E E3 9D       1359 ( 3) NAMEIN: LDX     #NAME+6
FD78-17 FB 04       1360 ( 9) NAM2:   LBSR    CONCHR          ; Get a character
FD7B-27 23          1361 ( 3)         BEQ     NAM1            ; no name
FD7D-81 20          1362 ( 2)         CMPA    #SPACE          ; if space
FD7F-27 F7          1363 ( 3)         BEQ     NAM2            ; ignore
FD81-81 2C          1364 ( 2)         CMPA    #COMMA
FD83-27 1B          1365 ( 3)         BEQ     NAM1            ; Null name
FD85-C6 FA          1366 ( 2)         LDB     #256-6          ; Minus name length
FD87-A7 85          1367 ( 6) NAM3:   STA     B,X             ; Store a letter
FD89-5C             1368 ( 2)         INCB                    ; and move up
FD8A-27 15          1369 ( 3)         BEQ     NAM6            ; Done 6 chars, exit
FD8C-17 FA F0       1370 ( 9)         LBSR    CONCHR          ; Get next letter
FD8F-27 08          1371 ( 3)         BEQ     NAM5            ; On CR, pad name
FD91-81 20          1372 ( 2)         CMPA    #SPACE          ; On space,
FD93-27 06          1373 ( 3)         BEQ     NAM4            ; pad name
FD95-81 2C          1374 ( 2)         CMPA    #COMMA          ; If not comma
FD97-26 EE          1375 ( 3)         BNE     NAM3            ; then use
FD99-86 20          1376 ( 2) NAM5:   LDA     #SPACE          ; padding
FD9B-A7 85          1377 ( 6) NAM4:   STA     B,X             ; Pad until
FD9D-5C             1378 ( 2)         INCB                    ; end of
FD9E-26 FB          1379 ( 3)         BNE     NAM4            ; name buffer
FDA0-39             1380 ( 5) NAM1:   RTS
FDA1-17 FA DB       1381 ( 9) NAM6:   LBSR    CONCHR          ; Get next input
FDA4-27 FA          1382 ( 3)         BEQ     NAM1            ; leave if CR
FDA6-81 2C          1383 ( 2)         CMPA    #COMMA          ; else
FDA8-27 F6          1384 ( 3) LFDA8:  BEQ     NAM1            ; absorb comma
FDAA-97 A2          1385 ( 4)         STA     <LASTC          ; else re-use
FDAC-39             1386 ( 5)         RTS
FDAD-               1387      ;
FDAD-               1388      ; Save files on cassette, dumps name block, data blocks as required in 256 byte blocks maximum,
FDAD-               1389      ; then end file block, can also inhibit end of file block
FDAD-               1390      ;
FDAD-9E 9D          1391 ( 5) SAVE:   LDX     <CSSTRT         ; Modify start address
FDAF-17 FE 31       1392 ( 9)         LBSR    NUMBX           ; if
FDB2-9F 9D          1393 ( 5)         STX     <CSSTRT         ; required
FDB4-9E 9F          1394 ( 5)         LDX     <CSEND          ; Modify end address
FDB6-17 FE 2A       1395 ( 9)         LBSR    NUMBX           ; if
FDB9-9F 9F          1396 ( 5)         STX     <CSEND          ; required
FDBB-8D B8          1397 ( 7)         BSR     NAMEIN          ; and get name
FDBD-C6 30          1398 ( 2)         LDB     #'0'            ; Output name,
FDBF-8D 3C          1399 ( 7)         BSR     XHEAD           ; header
FDC1-C6 06          1400 ( 2)         LDB     #6              ; name length
FDC3-30 1A          1401 ( 1)         LEAX    -6,X            ; Point to name,
FDC5-8D 46          1402 ( 7)         BSR     DATOUT          ; output name,
FDC7-8D 4E          1403 ( 7)         BSR     CHKOUT          ; then checksum.
FDC9-9E 9D          1404 ( 5)         LDX     <CSSTRT         ; Get start address
FDCB-34 10          1405 ( 7) SAV6:   PSHS    X               ; Save start
FDCD-DC 9F          1406 ( 5)         LDD     <CSEND          ; and get end address
FDCF-A3 E1          1407 (10)         SUBD    ,S++            ; Form length needed
FDD1-25 1D          1408 ( 3)         BLO     SAV2            ; Done all output
FDD3-4D             1409 ( 2)         TSTA                    ; If <=256 then
FDD4-27 03          1410 ( 3)         BEQ     SAV5            ; leave alone
FDD6-CC 00 FF       1411 ( 3)         LDD     #255            ; also set to 256
FDD9-33 8B          1412 ( 4) SAV5:   LEAU    D,X             ; Form end of block
FDDB-34 56          1413 (11)         PSHS    D,X,U           ; Put start/end on stack
FDDD-C6 31          1414 ( 2)         LDB     #'1'            ; Put a data
FDDF-8D 1C          1415 ( 7)         BSR     XHEAD           ; header.
FDE1-30 62          1416 ( 1)         LEAX    2,S             ; Point to start/end
FDE3-C6 04          1417 ( 2)         LDB     #4              ; Two words
FDE5-8D 26          1418 ( 7)         BSR     DATOUT          ; and put start/end out
FDE7-35 56          1419 (11)         PULS    D,X,U           ; Get all back
FDE9-5C             1420 ( 2)         INCB                    ; Modify length
FDEA-8D 21          1421 ( 7)         BSR     DATOUT          ; and send data bytes
FDEC-8D 29          1422 ( 7)         BSR     CHKOUT          ; then checksum
FDEE-20 DB          1423 ( 3)         BRA     SAV6            ; and repeat
FDF0-17 FA 8C       1424 ( 9) SAV2:   LBSR    CONCHR          ; Get input
FDF3-27 06          1425 ( 3)         BEQ     SAV3            ; On CR send of block
FDF5-81 2D          1426 ( 2)         CMPA    #'-'            ; If EOF inhibit
FDF7-27 1D          1427 ( 3)         BEQ     RTS1            ; then skip x9
FDF9-97 A2          1428 ( 4)         STA     <LASTC          ; Re-use input
FDFB-C6 39          1429 ( 2) SAV3    LDB     #'9'            ; Send EOF
FDFD-               1430      ;
FDFD-               1431      ; Routine to send header to block, header type in B.  Also initialises checksum in Y
FDFD-               1432      ;
FDFD-10 8E 00 00    1433 ( 4) XHEAD:  LDY     #0
FE01-31 3F          1434 ( 1) XH1:    LEAY    -1,Y            ; Loop
FE03-26 FC          1435 ( 3)         BNE     XH1             ; delay
FE05-86 D8          1436 ( 2)         LDA     #'X'+$80        ; Send an 'X' header marker
FE07-8D 13          1437 ( 7)         BSR     CASOPI          ; to cassette
FE09-1F 98          1438 ( 7)         TFR     B,A             ; Get type
FE0B-20 0F          1439 ( 3)         BRA     CASOPI          ; and send
FE0D-               1440      ;
FE0D-               1441      ; Data output routine, sends B data bytes starting from X
FE0D-               1442      ; (B zero means 256 bytes), X moves up by B bytes
FE0D-               1443      ;
FE0D-A6 80          1444 ( 7) DATOUT: LDA     ,X+             ; Get data
FE0F-31 A6          1445 ( 1)         LEAY    A,Y             ; Modify checksum
FE11-8D 09          1446 ( 7)         BSR     CASOPI          ; Send data
FE13-5A             1447 ( 2)         DECB                    ; Repeat until
FE14-26 F7          1448 ( 3)         BNE     DATOUT          ; zero count
FE16-39             1449 ( 5) RTS1:   RTS
FE17-               1450      ;
FE17-               1451      ; Send checksum to tape from Y, lower byte only
FE17-               1452      ;
FE17-1F 20          1453 ( 7) CHKOUT: TFR      Y,D            ; Checksum to D
FE19-1F 98          1454 ( 7)         TFR      B,A            ; then get low byte
FE1B-43             1455 ( 2)         COMA                    ; Want result $FF
FE1C-6E 9F E3 69    1456 ( 9) CASOPI: JMP     [CASOPA]        ; Send check byte
FE20-               1457      ;
FE20-               1458      ; Drive parameter specification
FE20-               1459      ;
FE20-               1460      DISCIT:                         ; Setup Drive
FE20-               1461                                      ; For Shugart drive
FE20-35             1462              .DB     $35             ; Command - Initialise 8271 (sent by CMDPAR)
FE21-04             1463              .DB     $04             ; Number of Parameters - 4
FE22-0D             1464              .DB     $0D             ; Parameter 1 Specify Initialise (i.e. not Bad Sectors)
FE23-14             1465              .DB     $14             ; Parameter 2 - Step Rate 40mS
FE24-05             1466              .DB     $05             ; Parameter 3 - Head Settling Time 10mS
FE25-AA             1467              .DB     $AA             ; Parameter 4 - Head Unload Time/Load Time 80mS/80mS
FE26-               1468
FE26-               1469      ;                               ; Drive Bad Tracks (sent by CMDPAR)
FE26-35             1470              .DB     $35             ; Command - Load Bad Tracks
FE27-04             1471              .DB     $04             ; Number of Parameters - 4
FE28-10             1472              .DB     DRIVE/$80*8+$10 ; Parameter 1 - either $10 (Drive 0) or change to $18 (Drive 1)
FE29-FF             1473              .DB     $FF             ; Parameter 2 - Bad Track No. 1 - none
FE2A-FF             1474              .DB     $FF             ; Parameter 3 - Bad Track No. 2 - none
FE2B-FF             1475              .DB     $FF             ; Parameter 4 - Current Track - none
FE2C-               1476      ;
FE2C-               1477                                      ; Mode Register Setup (sent by CMDPAR)
FE2C-7A             1478              .DB     $3A+DRIVE       ; Command - Write Special Register
FE2D-02             1479              .DB     $02             ; Number of Parameters - 2
FE2E-17             1480              .DB     $17             ; Parameter 1 - DMA Mode Register
FE2F-C1             1481              .DB     $C1             ; Parameter 2 -
FE30-               1482      ;
FE30-               1483                                      ; Load Head onto Disc, Start Motor (sent by CMDPAR)
FE30-7A             1484              .DB     $3A+DRIVE       ; Command - Write Special Register
FE31-02             1485              .DB     $02             ; Number of Parameters - 2
FE32-23             1486              .DB     $23             ; Parameter 1 - Drive Control Output Register
FE33-             S 1487              .DO     VER=490         ; (version 4.90 only)
FE33-             S 1488              .DB     $28+DRIVE       ; Parameter 2 - Fault Reset, Load Head
FE33-               1489              .FI
FE33-               1490              .DO     VER<>490        ; (versions 4.92 and 4.95)
FE33-48             1491              .DB     $08+DRIVE       ; Parameter 2 - Load Head
FE34-               1492              .FI
FE34-               1493      ;
FE34-               1494                                      ; Query Drive Ready (sent by DRVRDY)
FE34-6C             1495              .DB     $2C+DRIVE       ; Command - Read Drive Status
FE35-00             1496              .DB     $00             ; Number of Parameters - 0
FE36-               1497      ;
FE36-               1498      ;                               ; Seek to Track 0 (sent by CMDPAR)
FE36-69             1499              .DB     $29+DRIVE       ; Command - Seek
FE37-01             1500              .DB     $01             ; Number of Parameters - 1
FE38-00             1501              .DB     $00             ; Parameter 1 - Track 0
FE39-               1502      ;
FE39-               1503      ;                               ; Query Drive Ready (sent by DRVRDY)
FE39-6C             1504              .DB     $2C+DRIVE       ; Command - Read Drive Status
FE3A-00             1505              .DB     $00             ; Number of Parameters - 0
FE3B-               1506      ;
FE3B-               1507      ;                               ; Read Sector 1/2 (sent by CMDPAR)
FE3B-53             1508              .DB     $13+DRIVE       ; Command - Read Data Multi-sector
FE3C-03             1509              .DB     $03             ; Number of Parameters - 3
FE3D-00             1510              .DB     $00             ; Parameter 1 - Logical Track Address 0
FE3E-               1511
FE3E-             S 1512              .DO     VER=490         ; (original Acorn version 4.90 only)
FE3E-             S 1513              .DB     $02             ; Parameter 2 - Logical Sector Address 2
FE3E-               1514              .FI
FE3E-               1515              .DO     VER<>490        ; (version 4.92 and 4.95)
FE3E-01             1516              .DB     $01             ; Parameter 2 - Logical Sector Address 1
FE3F-               1517              .FI
FE3F-21             1518              .DB     $21             ; Parameter 3 - Sector Size - 256 bytes/sector
FE40-               1519                                      ;               Number of Sectors - 1 sector of 256 bytes
FE40-               1520      ;
FE40-             S 1521              .DO     VER<>492        ; (original Acorn version 4.90 and version 4.95)
FE40-             S 1522      ;                               ; Read Starting at Sector 3 (sent by CMDPAR)
FE40-             S 1523              .DB     $13+DRIVE       ; Command -  Read Data Multi-sector
FE40-             S 1524              .DB     $02             ; Number of Parameters - 2 (should be 3 ?)
FE40-             S 1525              .DB     $00             ; Parameter 1 - Logical Track Address 0
FE40-             S 1526              .DB     $03             ; Parameter 2 - Logical Sector Address 3
FE40-             S 1527                                      ; Parameter 3 - (missing should be $21 ?)
FE40-               1528              .FI
FE40-               1529              .DO     VER=492         ; (version 4.92 only)
FE40-FF FF FF FF    1530              .DB     $FF,$FF,$FF,$FF ; packing
FE44-               1531              .FI
FE44-               1532      ;
FE44-               1533      ; This routine bootstraps from a mini-floppy disc
FE44-               1534      ; Reads Sector 1/2 to find where to put program
FE44-               1535      ;
FE44-8E FF 04       1536 ( 3) BOOT:   LDX     #ANRTI          ; Set dummy interrupt routine
FE47-9F 83          1537 ( 5)         STX     <INMI
FE49-86 EA          1538 ( 2)         LDA     #FLOPY/256      ; Set direct page to 8271 FDC
FE4B-1F 8B          1539 ( 7)         TFR     A,DP
FE4D-               1540              .DP     FLOPY/256       ; and tell assembler
FE4D-8E FE 20       1541 ( 3)         LDX     #DISCIT         ; Point to Disk Info Tables
FE50-8D 4D          1542 ( 7)         BSR     CMDPAR          ; Set drive parameters
FE52-8D 4B          1543 ( 7)         BSR     CMDPAR          ; Set bad tracks
FE54-8D 49          1544 ( 7)         BSR     CMDPAR          ; Set mode register
FE56-8D 47          1545 ( 7)         BSR     CMDPAR          ; Load head, drive on
FE58-8D 5C          1546 ( 7)         BSR     DRVRDY          ; Check drive ready
FE5A-8D 43          1547 ( 7)         BSR     CMDPAR          ; Seek Track 0
FE5C-8D 58          1548 ( 7)         BSR     DRVRDY          ; Check drive ready
FE5E-8D 3F          1549 ( 7)         BSR     CMDPAR          ; Read Sector 2 (490) or 1 (495)
FE60-               1550      ;
FE60-             S 1551              .DO     VER=490         ; (original Acorn version 4.90 only)
FE60-             S 1552              LDU     #$0000          ; Put at $0000
FE60-               1553              .FI
FE60-               1554      ;
FE60-               1555              .DO     VER<>490        ; (versions 492 and 495)
FE60-CE C0 00       1556 ( 3)         LDU     #$C000          ; Put at $C000
FE63-               1557              .FI
FE63-               1558      ;
FE63-1F 32          1559 ( 7)         TFR     U,Y             ; and point to it
FE65-8D 62          1560 ( 7)         BSR     TRNSFR          ; Move disc data to memory
FE67-26 07          1561 ( 3)         BNE     DERR            ; Non-zero means error
FE69-               1562      ;
FE69-             S 1563              .DO     VER=490         ; (original Acorn version 4.90 only)
FE69-             S 1564              LDD     #$FF42          ; Check first two bytes are $FF42
FE69-             S 1565              CMPD    ,Y++
FE69-             S 1566              BNE     DERR            ; If not $FF42, no boot present
FE69-             S 1567              BSR     CMDPAR          ; Start read at sector 3
FE69-             S 1568              LDU     ,Y++            ; Get address to put at
FE69-             S 1569              LDA     ,Y+             ; and number of sectors
FE69-             S 1570              LDY     ,Y              ; Start of program
FE69-             S 1571              ADDA    #$20            ; Add sector length value
FE69-             S 1572      BOOT1:  LDB     <FDCS           ; Get FDC status and
FE69-             S 1573              BITB    #$20            ; if parameter register full
FE69-             S 1574              BNE     BOOT1           ; then wait
FE69-             S 1575              STA     <FDCP           ; Send number of sectors
FE69-             S 1576              BSR     TRNSFR          ; Move data to memory
FE69-             S 1577              BNE     DERR            ; Error if non-zero
FE69-             S 1578              LBSR    NUMB            ; Try get number
FE69-             S 1579              BVC     RTS2            ; Got one, stay in monitor
FE69-             S 1580              LDS     STACK           ; Reset stack and go to program
FE69-             S 1581              JMP     ,Y
FE69-               1582              .FI
FE69-               1583      ;
FE69-               1584              .DO     VER<>490        ; (version 4.92 and 4.95)
FE69-10 FE E3 5B    1585 ( 7)         LDS     STACK           ; Reset stack and go to program
FE6D-7E C0 00       1586 ( 4)         JMP     $C000
FE70-               1587              .FI
FE70-               1588      ;
FE70-8E FF CE       1589 ( 3) DERR:   LDX     #DQRY           ; Query user on display with error number
FE73-17 FA 76       1590 ( 9)         LBSR    STRING
FE76-17 FC 08       1591 ( 9)         LBSR    OPAREG
FE79-16 FA 6D       1592 (55)         LBRA    OPCRLF          ; Newline and exit
FE7C-               1593      ;
FE7C-               1594              .DO     VER=492         ; (version 4.92 only)
FE7C-FF FF FF FF 
     FF FF FF FF    1595              .DB     $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ; Packing
FE84-FF FF FF FF 
     FF FF FF FF    1596              .DB     $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF
FE8C-FF FF FF FF 
     FF FF FF FF    1597              .DB     $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF
FE94-FF FF FF FF 
     FF FF FF FF    1598              .DB     $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF
FE9C-FF FF FF       1599              .DB     $FF,$FF,$FF
FE9F-               1600              .FI
FE9F-               1601      ;
FE9F-             S 1602              .DO     VER=495         ; (version 4.95 only)
FE9F-             S 1603              LDY     #CRTCSV
FE9F-             S 1604              LDX     #$E300
FE9F-             S 1605              LDB     #$0B
FE9F-             S 1606      LFE85:  LDA     ,Y+
FE9F-             S 1607              STA     ,X+
FE9F-             S 1608              DECB
FE9F-             S 1609              BPL     LFE85
FE9F-             S 1610              LDA     <$01
FE9F-             S 1611              DECA
FE9F-             S 1612              STA     ,X+
FE9F-             S 1613              CLRA
FE9F-             S 1614              LDB     <$01
FE9F-             S 1615              LSRB
FE9F-             S 1616              STD     ,X++
FE9F-             S 1617              RTS
FE9F-             S 1618              .DB     $FF,$FF,$FF,$FF,$FF,$FF,$FF     ; Packing
FE9F-               1619              .FI
FE9F-               1620      ;
FE9F-               1621      ; This routine sends one command followed by a variable number of parameters, possibly none
FE9F-               1622      ; X points to command, next byte is number of parameters
FE9F-               1623      ; X left pointing after last parameter, destroys D
FE9F-               1624      ;
FE9F-EC 81          1625 ( 9) CMDPAR: LDD     ,X++            ; Get command (A) and number of parameters (B)
FEA1-0D 00          1626 ( 6) CP1:    TST     <FDCS           ; Test 8271 status and wait if busy
FEA3-2B FC          1627 ( 3)         BMI     CP1
FEA5-97 00          1628 ( 4)         STA     <FDCC           ; Send command
FEA7-5A             1629 ( 2) CP2:    DECB                    ; If no more parameters then exit
FEA8-2B 1E          1630 ( 3)         BMI     RTS2
FEAA-96 00          1631 ( 4) CP4:    LDA     <FDCS           ; If parameter register full then wait
FEAC-85 20          1632 ( 2)         BITA    #$20
FEAE-26 FA          1633 ( 3)         BNE     CP4
FEB0-A6 80          1634 ( 7)         LDA     ,X+             ; Get next parameter and send it
FEB2-97 01          1635 ( 4)         STA     <FDCP
FEB4-20 F1          1636 ( 3)         BRA     CP2             ; then repeat
FEB6-               1637      ;
FEB6-               1638      ; Test if drive ready, on entry X points to read drive status command sequence,
FEB6-               1639      ; on exit drive is ready and X points to next command sequence
FEB6-               1640      ;
FEB6-1F 13          1641 ( 7) DRVRDY: TFR     X,U             ; Save pointer
FEB8-1F 31          1642 ( 7) DR2:    TFR     U,X             ; Restore pointer
FEBA-8D E3          1643 ( 7)         BSR     CMDPAR          ; Ask for drive status
FEBC-96 00          1644 ( 4) DR1:    LDA     <FDCS           ; Wait until result ready
FEBE-85 10          1645 ( 2)         BITA    #$10
FEC0-27 FA          1646 ( 3)         BEQ     DR1
FEC2-96 01          1647 ( 4)         LDA     <FDCR           ; Get result
FEC4-85 04          1648 ( 2)         BITA    #$04            ; Ready bit mask
FEC6-27 F0          1649 ( 3)         BEQ     DR2             ; Not ready, wait
FEC8-39             1650 ( 5) RTS2:   RTS
FEC9-               1651      ;
FEC9-34 01          1652 ( 6) TRNSFR: PSHS    CC              ; Save CC while
FECB-1A 50          1653 ( 3)         ORCC    #$50            ; SEIF, set masks, disc is on NMI
FECD-C6 04          1654 ( 2)         LDB     #$04            ; Data available mask
FECF-20 04          1655 ( 3)         BRA     TRN2
FED1-96 04          1656 ( 4) TRN1:   LDA     <FDCD           ; Get data
FED3-A7 C0          1657 ( 7)         STA     ,U+             ; and store it
FED5-3C FF          1658 (20) TRN2:   CWAI    #$FF            ; Wait for interrupt
FED7-D5 00          1659 ( 4)         BITB    <FDCS           ; Check data available
FED9-26 F6          1660 ( 3)         BNE     TRN1
FEDB-35 01          1661 ( 6)         PULS    CC              ; Get interrupt masks back
FEDD-96 01          1662 ( 4)         LDA     <FDCR           ; then get result
FEDF-39             1663 ( 5)         RTS                     ; and return Z bit accordingly
FEE0-               1664      ;
FEE0-               1665      ; Interrupt request handler, comes here on IRQ active
FEE0-               1666      ; Checks for timer 1 or keyboard interrupt, if neither then complains to user
FEE0-               1667      ;
FEE0-86 E3          1668 ( 2) IRQHAN: LDA     #MONDP          ; Set up
FEE2-1F 8B          1669 ( 7)         TFR     A,DP            ; direct page
FEE4-               1670              .DP     MONDP           ; tell assembler
FEE4-8E E9 80       1671 ( 3)         LDX     #KVIA           ; Point to VIA address
FEE7-A6 0D          1672 ( 6)         LDA     KIFR-KVIA,X     ; Get flag register
FEE9-2A 1A          1673 ( 3)         BPL     UNUSED          ; Not the VIA!
FEEB-84 40          1674 ( 2)         ANDA    #T1IFLG         ; Try timer 1
FEED-27 06          1675 ( 3)         BEQ     LFEF5           ; Not timer 1
FEEF-A7 0D          1676 ( 6)         STA     KIFR-KVIA,X     ; Clear the interrupt
FEF1-6E 9F E3 73    1677 ( 9)         JMP     [IRQRTS]
FEF5-A6 0D          1678 ( 6) LFEF5:  LDA     KIFR-KVIA,X     ; Get flags again
FEF7-84 10          1679 ( 2)         ANDA    #CB1FLG         ; Try for keyboard
FEF9-27 0A          1680 ( 3)         BEQ     UNUSED          ; Query user if not
FEFB-A7 0D          1681 ( 6)         STA     KIFR-KVIA,X     ; Clear the interrupt
FEFD-               1682      ;
FEFD-               1683              .DO     VER<>495        ; (all versions except 4.95)
FEFD-A6 00          1684              .DB     $A6,$00         ; 'LDA  KIRB-KVIA,X'    ; and get a character
FEFF-               1685              .FI
FEFF-               1686      ;
FEFF-             S 1687              .DO     VER=495         ; (version 4.95 only)
FEFF-             S 1688              .DB     $A6,$84         ; 'LDA ,X'
FEFF-               1689              .FI
FEFF-               1690      ;
FEFF-84 7F          1691 ( 2)         ANDA    #$7F            ; stripping spare bit
FF01-17 FA FF       1692 ( 9)         LBSR    HAVCHR          ; Put into buffer
FF04-3B             1693 (15) ANRTI:  RTI                     ; then leave IRQ level
FF05-               1694      ;
FF05-               1695      ; Come here if unused interrupts are active, so complain to user and stop processor
FF05-               1696      ; since cannot clear an unknown interrupt
FF05-               1697      ;
FF05-8E FF CC       1698 ( 3) UNUSED: LDX     #IERR           ; Query user on display
FF08-17 F9 E1       1699 ( 9)         LBSR    STRING
FF0B-20 FE          1700 ( 3) FOREVR: BRA     FOREVR          ; and stop dead !
FF0D-               1701      ;
FF0D-               1702                                      ; *** VDU Configurations ***
FF0D-               1703      ;
FF0D-               1704      ;       R0      Horizontal Total Register               horizontal frequency, the total number of characters displayed and non-displayed per line
FF0D-               1705      ;       R1      Horizontal Displayed Register           number of displayed characters per line
FF0D-               1706      ;       R2      Horizontal Sync Position Register       position (start) of the horizontal sync
FF0D-               1707      ;       R3      (Horizontal) Sync Width Register        bits 0-3: width (character clocks) of the horizontal sync pulse
FF0D-               1708      ;                                                       bits 4-7: vertical sync pulse width in scan line times
FF0D-               1709      ;       R4      Vertical Total Register                 determines the vertical frequency (in character line times-1)
FF0D-               1710      ;       R5      Vertical Total Adjust Register          adjustment to vertical frequency (in scan line times)
FF0D-               1711      ;       R6      Vertical Displayed Register             number of displayed character rows
FF0D-               1712      ;       R7      Vertical Sync Position Register         position of the vertical sync pulse (character row times)
FF0D-               1713      ;       R8      Interlace & Skew Register               bits 0,1 control the raster scan mode
FF0D-               1714      ;                                                       bits 4,5 control DISPTMG skew
FF0D-               1715      ;                                                       bits 6,7 control cursor skew
FF0D-               1716      ;       R9      Maximum Scan Line Address Register      number of scan lines per character row - 1 (including spacing)
FF0D-               1717      ;       R10     Cursor Start Register                   bits 0-4 cursor start scan line
FF0D-               1718      ;                                                       bits 5,6 control the Cursor Display Mode
FF0D-               1719      ;                                                       bit 6 blink enable
FF0D-               1720      ;       R11     Cursor End Register                     cursor end scan line
FF0D-               1721      ;
FF0D-               1722                                      ; 40-Column Configurations
FF0D-               1723      ;
FF0D-             S 1724              .DO     VDU=40          ; Original Acorn Monitor Configurations from Manual
FF0D-             S 1725      ;
FF0D-             S 1726                                      ; For S Version 6845 CRT Controller (Interlaced)
FF0D-             S 1727      CRTCSV: .DB     $3F             ; R0    64 characters per line (15,625kHz)
FF0D-             S 1728              .DB     COLS            ; R1    40 displayed characters per line
FF0D-             S 1729              .DB     $34             ; R2    (52) start of horizontal sync - 52uS
FF0D-             S 1730              .DB     $44             ; R3    bits 0-3        (4) width of horizontal sync pulse - 4uS
FF0D-             S 1731                                      ;       bits 4-7        (4) vertical sync pulse width - 256uS
FF0D-             S 1732              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF0D-             S 1733              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF0D-             S 1734              .DB     ROWS            ; R6    25 displayed character rows
FF0D-             S 1735              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF0D-             S 1736              .DB     $03             ; R8    bits 0,1        3 = Interlace Sync & Video Mode
FF0D-             S 1737                                      ;       bits 4,5        0 = DISPTMG non-skew
FF0D-             S 1738                                      ;       bits 6,7        0 = Cursor non-skew
FF0D-             S 1739              .DB     $12             ; R9    (18) 20 scan lines/character (10 interlaced)
FF0D-             S 1740              .DB     $70             ; R10   bits 0-4        (16) cursor start scan line - 16
FF0D-             S 1741                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertical field rate
FF0D-             S 1742              .DB     $13             ; R11   bit 6           (19) underlined cursor
FF0D-             S 1743      ;
FF0D-             S 1744                                      ; For R Version 6845 CRT Controller (Non-Interlaced)
FF0D-             S 1745      CRTCRV: .DB     $3F             ; R0    64 characters per line (15,625kHz)
FF0D-             S 1746              .DB     COLS            ; R1    40 displayed characters per line
FF0D-             S 1747              .DB     $34             ; R2    (52) start of horizontal sync - 52uS
FF0D-             S 1748              .DB     $04             ; R3    bits 0-3        (0) width of horizontal sync pulse - 0uS
FF0D-             S 1749                                      ;       bits 4-7        (4) vertical sync pulse width - 256uS
FF0D-             S 1750              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF0D-             S 1751              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF0D-             S 1752              .DB     ROWS            ; R6    25 displayed character rows
FF0D-             S 1753              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF0D-             S 1754              .DB     $00             ; R8    bits 0,1        0 = Non-interlace Mode
FF0D-             S 1755                                      ;       bits 4,5        0 = DISPTMG non-skew
FF0D-             S 1756                                      ;       bits 6,7        0 = Cursor non-skew
FF0D-             S 1757              .DB     $09             ; R9    (9) 10 scan lines/character
FF0D-             S 1758              .DB     $68             ; R10   bits 0-4        (8) cursor start scan line - 8
FF0D-             S 1759                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertical field rate
FF0D-             S 1760              .DB     $09             ; R11   bit 6           (9) underlined cursor
FF0D-             S 1761      ;
FF0D-               1762              .FI
FF0D-               1763      ;
FF0D-             S 1764              .DO     VDU=41          ; Alternative Configurations which match System COS/DOS40B
FF0D-             S 1765      ;
FF0D-             S 1766                                      ; For S Version 6845 CRT Controller (Interlaced)
FF0D-             S 1767      CRTCSV: .DB     $3F             ; R0    64 characters per line (15,625kHz)
FF0D-             S 1768              .DB     COLS            ; R1    40 displayed characters per line
FF0D-             S 1769              .DB     $33             ; R2    (51) start of horizontal sync - 51uS
FF0D-             S 1770              .DB     $44             ; R3    bits 0-3        (4) width of horizontal sync pulse - 4uS
FF0D-             S 1771                                      ;       bits 4-7        (4) vertical sync pulse width - 256uS
FF0D-             S 1772              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF0D-             S 1773              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF0D-             S 1774              .DB     ROWS            ; R6    25 displayed character rows
FF0D-             S 1775              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF0D-             S 1776              .DB     $03             ; R8    bits 0,1        3 = Interlace Sync & Video Mode
FF0D-             S 1777                                      ;       bits 4,5        0 = DISPTMG non-skew
FF0D-             S 1778                                      ;       bits 6,7        0 = Cursor non-skew
FF0D-             S 1779              .DB     $12             ; R9    (18) 20 scan lines/character (10 interlaced)
FF0D-             S 1780              .DB     $72             ; R10   bits 0-4        (2) cursor start scan line -
FF0D-             S 1781                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertical field rate
FF0D-             S 1782              .DB     $13             ; R11   bit 6           (19) underlined cursor
FF0D-             S 1783      ;
FF0D-             S 1784                                      ; For R Version 6845 CRT Controller (Non-Interlaced)
FF0D-             S 1785      CRTCRV: .DB     $3F             ; R0    64 characters per line (15,625kHz)
FF0D-             S 1786              .DB     COLS            ; R1    40 displayed characters per line
FF0D-             S 1787              .DB     $33             ; R2    (51) start of horizontal sync - 51uS
FF0D-             S 1788              .DB     $04             ; R3    bits 0-3        (0) width of horizontal sync pulse - 0uS
FF0D-             S 1789                                      ;       bits 4-7        (4) vertical sync pulse width - 256uS
FF0D-             S 1790              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF0D-             S 1791              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF0D-             S 1792              .DB     ROWS            ; R6    25 displayed character rows
FF0D-             S 1793              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF0D-             S 1794              .DB     $00             ; R8    bits 0,1        0 = Non-interlace Mode
FF0D-             S 1795                                      ;       bits 4,5        0 = DISPTMG non-skew
FF0D-             S 1796                                      ;       bits 6,7        0 = Cursor non-skew
FF0D-             S 1797              .DB     $09             ; R9    (9) 10 scan lines/character
FF0D-             S 1798              .DB     $68             ; R10   bits 0-4        (8) cursor start scan line - 8
FF0D-             S 1799                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertical field rate
FF0D-             S 1800              .DB     $09             ; R11   bit 6           (9) underlined cursor
FF0D-             S 1801      ;
FF0D-               1802              .FI
FF0D-               1803      ;
FF0D-               1804                                      ; 80-Column Configurations
FF0D-               1805
FF0D-               1806              .DO     VDU=80          ; These configurations match the '41' config  (taken from System COS/DOS80B)
FF0D-               1807      ;
FF0D-               1808                                      ; For S Version 6845 CRT Controller (Interlaced)
FF0D-7F             1809      CRTCSV: .DB     $7F             ; R0    128 characters per line (31,250kHz)
FF0E-50             1810              .DB     COLS            ; R1    40 displayed characters per line
FF0F-60             1811              .DB     $60             ; R2    (96) start of horizontal sync - 96uS
FF10-28             1812              .DB     $28             ; R3    bits 0-3        (8) width of horizontal sync pulse - 4uS
FF11-               1813                                      ;       bits 4-7        (2) vertical sync pulse width - 256uS
FF11-1E             1814              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF12-02             1815              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF13-19             1816              .DB     ROWS            ; R6    25 displayed character rows
FF14-1B             1817              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF15-40             1818              .DB     $40             ; R8    bits 0,1        0 = Non-interlace Mode
FF16-               1819                                      ;       bits 4,5        0 = DISPTMG non-skew
FF16-               1820                                      ;       bits 6,7        4 = Cursor two-character skew
FF16-09             1821              .DB     $09             ; R9    (09) 20 scan lines/character (09 interlaced)
FF17-68             1822              .DB     $68             ; R10   bits 0-4        (8) cursor start scan line -
FF18-               1823                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertcial field rate
FF18-09             1824              .DB     $09             ; R11   bit 6           (09) underlined cursor
FF19-               1825      ;
FF19-               1826                                      ; For R Version 6845 CRT Controller (Non-Interlaced)
FF19-7F             1827      CRTCRV: .DB     $7F             ; R0    128 characters per line (31,250kHz)
FF1A-50             1828              .DB     COLS            ; R1    40 displayed characters per line
FF1B-60             1829              .DB     $60             ; R2    (96) start of horizontal sync - 96uS
FF1C-28             1830              .DB     $28             ; R3    bits 0-3        (8) width of horizontal sync pulse - 4uS
FF1D-               1831                                      ;       bits 4-7        (2) vertical sync pulse width - 256uS
FF1D-1E             1832              .DB     $1E             ; R4    (30) vertical frequency - 15.625kHz (31x10x64uS)
FF1E-02             1833              .DB     $02             ; R5    (2) adjustment to vertical frequency (2x64uS) giving a total of 19.968mS i.e. 50Hz (actually 50.08Hz)
FF1F-19             1834              .DB     ROWS            ; R6    25 displayed character rows
FF20-1B             1835              .DB     $1B             ; R7    (27) position of vertical sync pulse - 17.28mS
FF21-40             1836              .DB     $40             ; R8    bit 0,1         0 = Non-interlace Mode
FF22-               1837                                      ;       bits 4,5        0 = DISPTMG non-skew
FF22-               1838                                      ;       bits 6,7        4 = Cursor two-character skew
FF22-09             1839              .DB     $09             ; R9    (9) 10 scan lines/character
FF23-68             1840              .DB     $68             ; R10   bits 0-4        (8) cursor start scan line - 8
FF24-               1841                                      ;       bits 5,6        (1,1) blink enabled with frequency 1/32 of vertical field rate
FF24-09             1842              .DB     $09             ; R11   bit 6           (9) underlined cursor
FF25-               1843      ;
FF25-               1844              .FI
FF25-               1845      ;
FF25-               1846      ; Set up table 1, copied directly to RAM at RTAB1
FF25-               1847      ;
FF25-E3 5B          1848      PTAB1   .DW     ISTACK          ; Initial stack pointer
FF27-00 00          1849              .DW     0               ; Trace initially off
FF29-7F             1850              .DB     BSPACE          ; Character echoes on rubout
FF2A-FF             1851              .DB     $FF             ; Echo on, line buffer on
FF2B-00             1852              .DB     0               ; Printer off
FF2C-0A             1853              .DB     LF              ; Do not send line feeds, use CR only to printer
FF2D-00 CD          1854              .DW     BAUD            ; Initial baud rate for cassette
FF2F-F9 5B          1855              .DW     DISPLA          ; Console output
FF31-FA 5E          1856              .DW     GETCHR          ; Console input
FF33-FD 25          1857              .DW     MCASOP          ; Cassette output
FF35-FD 53          1858              .DW     MCASIN          ; Cassette input
FF37-FA 9D          1859              .DW     PRINT           ; Printer routine
FF39-FF 7F          1860              .DW     FUNCTS          ; Display function table
FF3B-FF 51          1861              .DW     CMNDS           ; Monitor command table
FF3D-FF 05          1862              .DW     UNUSED          ; Initial timer 1 routine
FF3F-00 00          1863              .DW     $0000           ; No memory interpret
FF41-FF 05          1864              .DW     UNUSED          ; Reserved vector
FF43-FF 05          1865              .DW     UNUSED          ; SWI3
FF45-FF 05          1866              .DW     UNUSED          ; SWI2
FF47-FF 05          1867              .DW     UNUSED          ; FIRQ
FF49-FE E0          1868              .DW     IRQHAN          ; IRQ
FF4B-FB C3          1869              .DW     SWIHAN          ; SWI
FF4D-FF 05          1870              .DW     UNUSED          ; NMI
FF4F-00 00          1871              .DW     $0000           ; Initial load offset
FF51-               1872      PTAB2:  .EQ     $               ; End of table
FF51-               1873      ;
FF51-               1874      ; This table contains the standard set of commands provided by the monitor
FF51-               1875      ;
FF51-0E             1876      CMNDS:  .DB     CMNDE-CMNDS/3-1 ; Number of entries
FF52-47             1877              .AS     'G'
FF53-FC B0          1878              .DW     GOUSER-CMNDS    ; Go to program
FF55-4D             1879              .AS     'M'
FF56-FB B0          1880              .DW     MEM-CMNDS       ; Memory examine
FF58-52             1881              .AS     'R'
FF59-F9 67          1882              .DW     EXREG-CMNDS     ; Examine registers
FF5B-50             1883              .AS     'P'
FF5C-FC 68          1884              .DW     RESUME-CMNDS    ; Proceed after break
FF5E-54             1885              .AS     'T'
FF5F-FD 10          1886              .DW     TRACEN-CMNDS    ; Set trace number
FF61-53             1887              .AS     'S'
FF62-FE 5C          1888              .DW     SAVE-CMNDS      ; Save on cassette
FF64-4C             1889              .AS     'L'
FF65-FD 50          1890              .DW     LOAD-CMNDS      ; Load from cassette
FF67-56             1891              .AS     'V'
FF68-FC D2          1892              .DW     BRKSET-CMNDS    ; Set break address
FF6A-44             1893              .AS     'D'
FF6B-FE F3          1894              .DW     BOOT-CMNDS      ; Disc bootstrap
FF6D-43             1895              .AS     'C'
FF6E-FD 29          1896              .DW     PCNTL-CMNDS     ; Copy to printer
FF70-20             1897              .DB     SPACE
FF71-FB 0C          1898              .DW     ANRTS-CMNDS     ; Ignore spaces
FF73-2C             1899              .DB     COMMA
FF74-FB 0C          1900              .DW     ANRTS-CMNDS     ; Ignore commas
FF76-2E             1901              .AS     '.'
FF77-FD 16          1902              .DW     TRACE-CMNDS     ; Do trace operation
FF79-46             1903              .AS     'F'
FF7A-FD 77          1904              .DW     LOAD7-CMNDS     ; Finish file load
FF7C-01             1905              .DB     1
FF7D-FD 38          1906              .DW     BADCMD-CMNDS    ; Default is query user
FF7F-               1907      CMNDE:  .EQ     $
FF7F-               1908      ;
FF7F-               1909      ; This table contains the standard functions provided by the VDU control programs
FF7F-               1910      ;
FF7F-               1911      FUNCTS:
FF7F-               1912              .DO     VER<>495        ; (all versions except 4.95)
FF7F-04             1913              .DB     FUNCTE-FUNCTS/3-1 ; Number of entries
FF80-               1914      ;
FF80-0D             1915              .DB     CR              ; Carriage return
FF81-FA 6D          1916              .DW     DOCR-FUNCTS
FF83-               1917      ;
FF83-0A             1918              .DB     LF              ; Linefeed
FF84-F9 F8          1919              .DW     DOLF-FUNCTS
FF86-               1920      ;
FF86-7F             1921              .DB     BSPACE          ; Backspace
FF87-FA 06          1922              .DW     DORUB-FUNCTS
FF89-               1923      ;
FF89-0C             1924              .DB     FFEED           ; Form feed
FF8A-F9 A6          1925              .DW     CRTCI-FUNCTS
FF8C-               1926      ;
FF8C-01             1927              .DB     1
FF8D-F9 EA          1928              .DW     SIMCHR-FUNCTS   ; Default is display it
FF8F-               1929              .FI
FF8F-               1930      ;
FF8F-             S 1931              .DO     VER=495         ; (version 4.95 only)
FF8F-             S 1932              .DB     FUNCTE-FUNCTS/3 ; Number of entries
FF8F-             S 1933      ;
FF8F-             S 1934              .DB     CR              ; Carriage return
FF8F-             S 1935              .DW     DOCR-FUNCTS
FF8F-             S 1936      ;
FF8F-             S 1937              .DB     LF              ; Linefeed
FF8F-             S 1938              .DW     DOLF-FUNCTS
FF8F-             S 1939      ;
FF8F-             S 1940              .DB     $08             ; Backspace ??
FF8F-             S 1941              .DW     DORUB-FUNCTS
FF8F-             S 1942      ;
FF8F-             S 1943              .DB     $01             ; Form feed
FF8F-             S 1944              .DW     $F9EA           ; CRTCI-FUNCTS  ; $F9EA ??
FF8F-             S 1945              .DB     1
FF8F-             S 1946              .DW     SIMCHR-FUNCTS   ; Default is display it
FF8F-               1947              .FI
FF8F-               1948      ;
FF8F-               1949      FUNCTE: .EQ     $
FF8F-               1950      ;
FF8F-               1951      ; This is the list of strings used by the monitor
FF8F-               1952      ;
FF8F-52 6F 6D 3F    1953      MQRY:   .AS     "Rom?"
FF93-0D 0A 00       1954      SCRLF:  .DB     CR,LF,0
FF96-43 43 20 20 
     41 20 20 42 
     20 44 50 20 
     20 20 20 58 
     20 20 20 20 
     59 20 20 20 
     20 55 20 20 
     20 50 43 20 
     20 20 20 53    1955      TITLES: .AS     "CC  A  B DP    X    Y    U   PC    S"
FFBA-0D 0A 00       1956              .DB     CR,LF,0
FFBD-0D 0A          1957      PCMESS: .DB     CR,LF
FFBF-50 43 5D       1958              .AS     "PC]"
FFC2-00             1959              .DB     0
FFC3-57 68 61 74 
     20 69 73 3A    1960      CQRY:   .AS     "What is:"
FFCB-00             1961              .DB     0
FFCC-49             1962      IERR:   .AS     'I'
FFCD-2D             1963      LQRY:   .AS     '-'
FFCE-45 72 72 20    1964      DQRY:   .AS     "Err "
FFD2-00             1965              .DB     0
FFD3-               1966      ;
FFD3-               1967      ; This is the set of indirect jumps to redirect the interrupt vector addresses
FFD3-               1968      ;
FFD3-6E 9F E3 77    1969 ( 9) RESVI:  JMP     [IRESV]
FFD7-6E 9F E3 79    1970 ( 9) SWI3I:  JMP     [ISWI3]
FFDB-6E 9F E3 7B    1971 ( 9) SWI2I:  JMP     [ISWI2]
FFDF-6E 9F E3 7D    1972 ( 9) FIRQI:  JMP     [IFIRQ]
FFE3-6E 9F E3 7F    1973 ( 9) IRQI:   JMP     [IIRQ]
FFE7-6E 9F E3 81    1974 ( 9) SWII:   JMP     [ISWI]
FFEB-6E 9F E3 83    1975 ( 9) NMII:   JMP     [INMI]
FFEF-               1976      ;
FFEF-               1977      ; The following hardware vectors reside in the top 16 bytes of memory
FFEF-               1978      ; when the monitor is in its standard position
FFEF-               1979      ;
FFEF-             S 1980              .DO     VER=490         ; (original Acorn version 4.90 only)
FFEF-             S 1981              .DB     $00             ; packing
FFEF-               1982              .EL                     ; (all other versions)
FFEF-FF             1983              .DB     $FF             ; packing
FFF0-               1984              .FI
FFF0-               1985      ;
FFF0-FF D3          1986              .DW     RESVI
FFF2-FF D7          1987              .DW     SWI3I
FFF4-FF DB          1988              .DW     SWI2I
FFF6-FF DF          1989              .DW     FIRQI
FFF8-FF E3          1990              .DW     IRQI
FFFA-FF E7          1991              .DW     SWII
FFFC-FF EB          1992              .DW     NMII
FFFE-F8 00          1993              .DW     RESET